Here's a technique I use: open the original file and a new file (the latter for writing). loop through the original file. If the incoming line matches the pattern you're looking for, set a flag to true. Print the incoming line to the outgoing file unless the flag is set. Then, check to see if the line matches the pattern that ends the block you're cutting out. If so, set the flag back to false. If you don't have an explicit ending line (e.g. here you've got a nice XMLish closing tag, but you might have a file like:

Server a.b.c.d
 line 1
 line 2
Server e.f.g.h
 line 1

You can monkey with the inner logic of the loop to deal with such situations, but that's left as an exercise for the reader =)

open OLD, $oldfile or die;
open NEW, "> $oldfile.new" or die;
my $flag = 0;
while (<OLD>) {
 $flag =1 if /pattern/;
 print NEW unless $flag;
 $flag = 0 if /end_pattern/;
}
rename ("$oldfile", "$oldfile.old") or die;
rename ("$oldfile.new", $oldfile) or die;
[download]

Of course, you'd replace my dies with more helpful messages, and substitute real patterns for mine.

HTH

Philosophy can be made out of anything. Or less -- Jerry A. Fodor

Looks like brendonc needs to see if the _next_ line matches. So maybe

  $flag =1 if /pattern/;
  print NEW $lastln unless $flag;
  $lastln = $_;
  if ($flag and /end_pattern/) {
    $lastln = '';
    $flag = 0;
  }
[download]

?

p

($^I,@ARGV)=('.bak','file.txt');
while(<>){
my $c=$_=~/<VirtualHost.*>/..$_=~m!</VirtualHost>!;
print unless $c;
if($c==2){($ServerName)=/ServerName (.*)$/}
}
[download]

You should be able to find out about the .. in perlop.

my $line;
while ($line = <CONF>) {
    my $string;

    # check for start of virtual host block    

    if ( $line =~ /^\s*\<VirtualHost/ ) {
        $string = $line;  #no chomp

        # read in the enter virtualhost block...

        do {
            $line = <CONF>;
            $string = $string . $line;
        } until $line =~ /^s*\<\/VirtualHost\>/;

        # Find the server name

        $string =~ /ServerName\s+(.*)\s/;

        # Ignore it if necessary...you can add a number of checks here
        # including multple servers that you want to ignore.

        if ( $1 ne "my.domain.here" ) {
            print <CONF.NEW> $string;
        }
    } else {
        # if not a virtual server line, just pass it through.
        print <CONF.NEW> $line;
    }
}
[download]

#! perl -w

use strict;

$/ = undef;
my $data = <DATA>;

my @fields = split /(?<=\n)(<\/?VirtualHost.*>[ \t]*\n)/, $data;

printf "sanity check before: %d fields\n", scalar @fields;

for (my $i = $#fields-2; $i >= 0; --$i) {
    if ($fields[$i] =~ m(<VirtualHost.*>[ \t]*\n)   &&
        $fields[$i+1] =~ m(ServerNameTwo)    &&
        $fields[$i+2] =~ m(<\/VirtualHost>[ \t]*\n)
    ) {
        splice @fields, $i, 3;
    }
}

printf "sanity check after: %d fields\n", scalar @fields;
print join '', @fields;


__END__

### mock httpd.conf file used as test data ###

Hello everyone, This is my first post. I've been search 
through previous posts and several Perl books but I haven't 
been able to find a solution to my problem. I'm quite 
new to Perl by the way. Here's the problem. I need to 
parse a httpd.conf file and remove a VirtualHost block. 
It looks like this: 


<VirtualHost 123.123.123.123>
    ServerNameOne www.domain.com
    ...
</VirtualHost>

I need to be able to parse the file, find the 
appropriate ServerName, and then remove that entire VHost block. 
I'm stuck on this one. If anyone can help I would greatly appreciate i
+t. 
Thanks, Brendon


<VirtualHost 123.123.123.123>
    ServerNameTwo www.domain.com
    ...
</VirtualHost>

qwertzuiop...

<SomeOtherBlock>
qwertzuiop...

</SomeOtherBlock>


<VirtualHost 123.123.123.123>
    ServerNameThree www.domain.com
    ...
</VirtualHost>

qwertzuiop...
qwertzuiop...
qwertzuiop...
[download]

Hi if need to remove multiple domains from a different text file and change

 $fields[$i+1] =~ m(ServerNameTwo)
[download]

into

 $fields[$i+1] =~ m($domainvariable)
[download]

is not working.