use strict;
use warnings;

my @array1 = (
    'abc abc abc abc abc',
    'abc abc abc2 abc3 abc4 abc5',
    'abc abc abc1 abc2',
    );
my @array2;

for (@array1) {
    push @array2, $_;
    $array2[-1] =~ s/\s+//g;
}

print "@array2";
[download]

Prints:

abcabcabcabcabc abcabcabc2abc3abc4abc5 abcabcabc1abc2
[download]

# assuming @array1 contains the values to change.

my @array2 = @array1;
@array2 = map { s/\s//g; $_ } @array2;

print @array2;
[download]

Slightly cleaner:

my @array2 = @array1;
s/\s+//g for (@array2);
[download]

Or in a single statement:

my @array2 = map {(my $x = $_) =~ s/\s+//g; $x} @array1;
[download]

The main concern you must have when dealing with map and a regex is not destructing the original array unless you truly intend to. $_ is an alias to each element of the source array, so any modification of it modifies the original array. To avoid this we assign to a temporary lexical in the above map block. And then finally make sure to return the actual variable and not a count of the number of substitutions.

Personally, I'd probably just stick with your original code, as I kind of doubt that you truly need a second array with these crunched values. Instead simply add the "crunching" as part of the loop for whatever other processing that you intend to be doing. Whatever that may be.

- Miller

thanks guys, it's working. I still dont' understand map too well(along with many other things).. can someone show me a URL that has map tutorial better than http://perldoc.perl.org/functions/map.html ?? Their explanation on how to mix it in with other does not make much sense to me.

You can simply join the statements

my @array2 = @array1;
s/\s+//g for (@array2);
[download]

into one:

tr/ //d for my @array2 = @array1;
[download]

The tr/// here only treats blanks instead of general white space, but that's easily changed if necessary.

Anno

I like brief too ... why not simply:?

my @array2 = map { s/\s+//g; $_ } @array1;
[download]

Update  Whoops, now I see ... it's because you'd be changing the original array.  Still, I like the brevity of something like:

my @array2 = map { (my $x = $_) =~ s/\s+//g; $x } @array1;
[download]

---

s''(q.S:$/9=(T1';s;(..)(..);$..=substr+crypt($1,$2),2,3;eg;print$..$/

Because that mangles @array1 - $_ is aliased to each element from @array1 and the substitution clobbers the original value

---

DWIM is Perl's answer to Gödel

tr/ //d for @array2;

will probably be a tad faster, in that it transliterates, and avoid using a code block.

• another intruder with the mooring in the heart of the Perl

@array1
abc abc abc abc abc
abc abc abc2 abc3 abc4 abc5
abc abc abc1 abc2
[download]

@array1 = (
  'abc abc abc abc abc',
  'abc abc abc2 abc3 abc4 abc5',
  'abc abc abc1 abc2'
);
[download]

use Data::Dumper;
$Data::Dumper::Useqq=1;
print Dumper \@array;
[download]

That will update @array1. OP implied that @array2 should have the updated strings. Of course it may be that OP intended the two arrays to actually represent the contents of an unspecified array at two different time, in which case:

s/\s+//g for @fields;
[download]

may be what OP is looking for.

I find it a little tricky to read some OP's minds at times. ;)

---

DWIM is Perl's answer to Gödel