my @words = map { split } <FH>;
[download]

Four things are happening here...

• <FH> is being evaluated in list context because of map. So it will return a list of lines from FH.
• split will take each of those lines in turn, and split them by it's default, which is whitespace (it's more complicated than that, see split for the details). split returns a list of the words in a line
• map takes each list returned by split and adds them to @words
• @words ends up as an array of words, taken from each line in your file.

Why is this evaluating split of array to scalar?

Because it's within a string. Perl evaluates print "\@lines1 is @lines1" as print '@lines1 is ' . @lines1. Concatenation forces scalar context on its operands. scalar @lines1 returns the number of element in the array.

See my reply below for the real answer to this.

print "@lines1" is treated magically: each element of @lines1 is printed, separated by a space.

update: ysth pointed out that what I'd written was wrong. Sorry about that.

Hi, I am running below and getting scalar value, I thought splitting up array into array would give me list context

~/script/perl/temp@myserver >cat perl.map2
#!/usr/bin/perl -w


use strict;

open (FH, 'foo.txt');
my @lines = <FH>;
close FH;
my @lines1 = split(' ', @lines);
print "@lines1\n";



#hi how are you
#i am fine
~/script/perl/temp@myserver >./perl.map2
2
[download]

Yet again, it's all about context:

my @lines1 = split(' ', @lines);
[download]

split expects a regexp and a string as arguments, which are both scalars. @lines is evaluated in scalar context, returning the number of elements it contains. So, split has nothing to split, and returns the number of elements to be assigned to @lines1.

Simply put, you can't split arrays. The purpose of split is to split a string into a list of values. Therefore, split expects a scalar as its second argument, representing the string to split. When you pass an array, the array is evaluated in scalar context, which returns the number of elements in the array.

If you wanted to split each of the lines, you should use a foreach loop to iterate over the values in the array and operate on them one at a time:

foreach (@lines) {
   my @lines1 = split(' ', $_); # $_ is "it" -- the current element of
+ @lines
   print @lines1,"\n";
}
[download]

Or, for another approach, you could use map:

map { print split(' ', $_),"\n" } @lines;
[download]

In any case, split simply does not, will not work they way you're trying to use it -- it's not supposed to.

<–radiant.matrix–>
Ramblings and references
The Code that can be seen is not the true Code
I haven't found a problem yet that can't be solved by a well-placed trebuchet

Sigh. Read I know what I mean. Why don't you?. It has some hints for writing posts so that other people understand what you are asking and so that code you provide can be run by others with the least hassle and external dependencies.

Where are the code samples that generate the output you show?. Why can't I see the link to the tutorial you mention?

How often do you check the perlintro documentation when you have a problem? Something simple you can probably do at your command line is: perldoc -f <func name>. For example you could perldoc -f split to get split which would tell you that split works on an 'EXPR' (i.e. string in this case), not an array.

thanks for your pointer.. and you r right.. I should read up more on these..
** update ** I acheived what I wanted w/ below code
I ran into this while going through map tutorial and
wanted to see if I can write the same code using w/out map
But you had me realize that I need to get more through with
basic stuff as well as writing clear questions
thanks for all your help guys~


use strict;

open (FH, 'foo.txt');
my @lines = <FH>;
my @lines1;
close FH;
foreach  (@lines) {
  chomp;
  push my @lines1, $_; 
}
print "@lines1\n";
[download]

Note that chomp can act on an array so you can:

use strict;
use warnings;

my $file1 = <<FILE;
apple
goat
chocolate
newyork
FILE

open IN, '<', \$file1;
my @lines = <IN>;
close IN;

chomp @lines;
print "@lines1\n";
[download]

Prints:

apple goat chocolate newyork
[download]

---

DWIM is Perl's answer to Gödel

Seems to me like you want to get rid of the map. You can replace map with another loop.

@array = map { EXPR } LIST;
[download]

is functionally equivalent to

@array = ();
foreach (LIST) {
   push @array, EXPR;
}
[download]

So

open (FH, "foo.txt");
my @words = map { split } <FH>;
close FH;
print "@words\n";
[download]

can be written as

open (FH, "foo.txt");
my @words;
foreach (<FH>) {
   push @words, split;
}
close FH;
print "@words\n";
[download]

Since <FILE> can be used as an interator, the following is more memory-efficient:

open (FH, "foo.txt");
my @words;
while (<FH>) {
   push @words, split;
}
close FH;
print "@words\n";
[download]