Since you said "array", you can use \$_ == \$array[-1]:

my @array= ( 1..5 );
for( @array ) {
    if(  \$_ == \$array[-1]  ) {
        print "Last element.\n";
    }
    print $_, $/;
}
__END__
1
2
3
4
Last element.
5
[download]

Update: ikegami asked about Data::Alias being able to confuse this test. Yes, that can be done, and one can even do it w/o such a module but it requires some unusual contortions and so probably isn't something to worry too much about:

my $five= 5;
*array= sub { \@_ }->( 1, 2, $five, 4, $five );
for( @array ) {
    if(  \$_ == \$array[-1]  ) {
        print "Last element.\n";
    }
    print $_, $/;
}
__END__
1
2
Last element.
5
4
Last element.
5
[download]

In the CB, I presented:

for my $i (0..$#array) {
   for ($array[$i]) {
      ...
      if ($i == $#array) { ... }
      ...
   }
}
[download]

Using this method, no change will be required to the body of your loop. $_ is still aliased to the array element as it normally is in a foreach loop. Changes to it will be reflected in the array.

Yet another variant:

my @elems = qw(a b c d e);

my $n = $#elems;
for my $elem (@elems) {
    print "last elem = $elem\n" if !$n--;
}
[download]

Update: as to your updated question: if you want to avoid creating a named array at any price, you could do something like this (but I'm not sure if I should seriously recommend that...)

my $n;
for my $elem (map {$n++; $_} qw(a b c d e)) {
    print "last elem = $elem\n" if !--$n;
}
[download]

With your update, you could just assign the returned list to a named array. Or, for fun, do something crazy like:

sub children { return ( 1..5 ); }
my( $end, $subcat );
foreach my $next (  children(), $end  ) {
    if(  ! $end  ) {
        $end= 1;
        $subcat= $next;
        next;
    }
    if(  \$next == \$end  ) {
        print "Last element.\n";
    }

    print $subcat, $/;

    $subcat= $next;
}
__END__
1
2
3
4
Last element.
5
[download]

my @array = (1 .. 10);
my $counter;
foreach my $element (@array) {
    print "Last element follows now!\n"    if ++$counter == scalar(@ar
+ray);
    print "$element\n";
}
[download]

Output:

1
2
3
4
5
6
7
8
9
Last element follows now!
10
[download]

You can leave out the scalar function but then you have to take care that the test does not get evaluated in list context.

my @children = $category->children;
for my $i (0..$#children) {
    my $subcat = $children[$i];
    my $is_last = $i == $#children;
    
    # More code here.
}
[download]

my @children   = $category->children;
my $last_child = pop @children;

foreach $child (@children) {
    handle_not_last_child($child);
}

handle_last_child($last_child);
[download]

Nice mvc++, I like your solution.

my $LastSubCat;

foreach my $subcat ($category->children) { 
      $LastSubCat = $subcat;
      # Code to use $subcat 
}

# $LastSubCat now contains the value of the last element
[download]