Problems of varying importance:

• use strict; and use warnings; are missing, hidding some errors.
• split is misspelled.
• Most variables are not declared.
• Some sigils are missing.
• $arry_hash contains a reference to a scalar (\$arry_hash) instead of a reference to an array (\@arry_hash) as it should.
• Unsafe 2-arg open is used.
• The file is closed at a different level than the one at which it was opened.

Fixed:

use strict;
use warnings;

use Data::Dumper qw( Dumper );

sub create_array {
   my ($fh) = @_;
   my @data;
   while (<$fh>) {
       chomp();
       my %record;
       for my $field (split ',') {
           my ($key, $value) = split /=/, $field;
           $record{$key} = $value;
       }
       push @data, \%record;
   }
   return \@data;
}


# open(my $infh, '<', $myfile)
#    or die("Unable to open data file \"$myfile\": $!\n");
# my $data = create_array($infh);
# close($infh);
my $data = create_array(*DATA);

print(Dumper($data));

__DATA__
A2=ABCD,A3=0123
A2=QWER,A3=4567
A2=ASDF,A3=7890
[download]