%hash = (
    a => '15-19,30,35,120',
    b => '15-17,30-35,40',
    c => '15-18,30,35,120',
);

for (keys %hash ) {
    ($s = $hash{ $_}) =~ s/-/../g;
    $hash{$_} = join(',',eval $s);
};
print "$_ => $hash{$_}\n" for sort keys %hash;
__END__
a => 15,16,17,18,19,30,35,120
b => 15,16,17,30,31,32,33,34,35,40
c => 15,16,17,18,30,35,120
[download]

_($_=" "x(1<<5)."?\n".q·/)Oo.  G°\        /
                              /\_¯/(q    /
----------------------------  \__(m.====·.(_("always off the crowd"))."·
");sub _{s./.($e="'Itrs `mnsgdq Gdbj O`qkdq")=~y/"-y/#-z/;$e.e && print}

while ( <DATA> ) {
    chomp;
    my ( $lhs, $rhs ) = split /\s+=>\s+/;
    my $ans = "$lhs => " .
        join ",",
            map { /(\d+)-(\d+)/ ? $1 .. $2 : $_ }
                split /,/;
    print "$ans\n"
}
__DATA__
a => 15-19,30,35,120
b => 15-17,30,35,40,
c => 15-18,30,35,120
__END__
a => 15,16,17,18,19,30,35,120
b => 15,16,17,30,35,40
c => 15,16,17,18,30,35,120
[download]

Since you didn't provide any code, I'll assume that you know how to iterate over the keys of the hash, etc.

If the list of numbers and ranges in each value is in numerical order, you could use Set::IntSpan. If you need more help, please be more specific. Also, don't forget about Super Search. number sequence offers many solutions that solve this problem - please refer to that node for more information.

It's not entirely clear what format your initial data structure is taking. Are the values a single string? Are an array of values?

Assuming that they are array refs, and that your ranges are ordered from lesser value to greater value, this should work just fine:

my %hash = (
    a => ['15-19',30,35,120],
    b => ['15-17','30-35',40],
    c => ['15-18',30,35,120],
);

for (values %hash) {
    @$_ = map {/^(\d+)-(\d+)$/ ? ($1..$2) : $_} @$_;
}

use Data::Dumper;
print Dumper(\%hash);
[download]

for (values %hash) {
    @$_ = map {!/^(\d+)-(\d+)$/ ? $_ : ($1 < $2) ? ($1..$2) : reverse 
+($2..$1)} @$_;
}
[download]

This would allow negatives:

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my $test = {
   a => '-15-19,30,35,120',
   b => '15-17,30,35,40',
   c => '15-18,30,35,120'
};


for my $key (keys %$test) {
   print "Processing '$key'\n";
   $test->{$key} = [
                     map { /(-?\d+)-(-?\d+)/ ? ($1..$2) : 0+$_ }
                     split(',', $test->{$key})
                   ];
}

print Dumper($test);
[download]

And one more with regex:

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my $test = {
   a => '-15-19,30,35,120',
   b => '15-17,30,35,40',
   c => '15-18,30,35,120'
};


for my $key (keys %$test) {
   print "Processing '$key'\n";
   $test->{$key} =~ s/(-?\d+)-(-?\d+)/join(",", ($1..$2))/eg;
   $test->{$key} = [split(',', $test->{$key} )];
}

print Dumper($test);
[download]


___________
Eric Hodges

On the other hand, it is certainly not a smart idea to store this way. The original format makes much more sense.