in reply to Re^2: XML::Simple for sequence in xsd
in thread XML::Simple for sequence in xsd

Here's an example of how to use Tie::IxHash: 
use strict;
use warnings;
use Tie::IxHash;

my %myhash;
my %myotherhash;

tie %myhash, 'Tie::IxHash';
for (my $i=0; $i<7; $i++) {
    $myhash{$i} = 2*$i;
}
my @keys = keys %myhash;
print "@keys\n";

for (my $i=0; $i<7; $i++) {
    $myotherhash{$i} = 2*$i;
}
@keys = keys %myotherhash;
print "@keys\n";

__END__
Output:
0 1 2 3 4 5 6
6 4 1 3 0 2 5

[download]
Note that %myhash preserves the order, whereas %myotherhash (which is not tied to Tie::IxHash) does not preserve the order.

If you still have trouble with the error you experienced it's probably best to provide some code that demonstrates the problem. (Try to provide a small script that demonstrates the problem.)

Cheers,
Rob

Replies are listed 'Best First'.
Re^4: XML::Simple for sequence in xsd
by moritz (Cardinal) on Aug 18, 2007 at 16:28 UTC
    It works in combination with XML::Simple: 

    use strict;
use warnings;
use Tie::IxHash;
use XML::Simple;

my %myhash;

tie %myhash, 'Tie::IxHash';
$myhash{foo1} = 'bar1';
$myhash{foo3} = 'bar3';
$myhash{foo2} = 'bar2';
$myhash{foo4} = 'bar4';
$myhash{foo5} = [qw(bar5a bar5b bar5c)];

print XMLout(\%myhash, NoSort => 1);

    [download]

    And the output: 

    <opt foo1="bar1" foo3="bar3" foo2="bar2" foo4="bar4">
  <foo5>bar5a</foo5>
  <foo5>bar5b</foo5>
  <foo5>bar5c</foo5>
</opt>

    [download]

    And without the tie: 

    <opt foo3="bar3" foo4="bar4" foo2="bar2" foo1="bar1">
  <foo5>bar5a</foo5>
  <foo5>bar5b</foo5>
  <foo5>bar5c</foo5>
</opt>

    [download]

    Alternatively the data could be written with XML::Twig or other XML modules.

[reply]
[d/l]
[select]
Re^4: XML::Simple for sequence in xsd
by Sham (Novice) on Aug 20, 2007 at 06:34 UTC
    Hi Rob, Tying up the hash is done fantastically with the Tie::IxHash module. But when I pass the this tied hash to the XML::Simple it no more follow the tie for the hash. I am trying to get the XML nodes in the sequence which I am following to create the hash elements. Following is the sample code and the output which I am trying to get correct result. If I am missing somewhere please suggest. 
    use strict;
use XML::Simple;
use Data::Dumper;
use Tie::IxHash;

my     $Request_data = {};

tie my %NewOrder_data , 'Tie::IxHash';

 %NewOrder_data =  (        
                    'IndustryType'        => ['EC'], 
                    'CurrencyCode'        => ['840'],
                    'CurrencyExponent1'    => ['1'],
                    'CurrencyExponent2'    => ['2'],
                    );



my @keys = keys %NewOrder_data;
print "\n@keys\n";

    my $xmlDS = {
        Request => [
                {                
                NewOrder => [
                                {
                                %NewOrder_data,
                                }
                            ],
                    }
            ],
        };



my $request_xml = eval {
    my $xs = new XML::Simple(keeproot => 1, SuppressEmpty => 1);
    $xs->XMLout($xmlDS);
    };

print STDERR "\n\nxml :- >\n" . Dumper($request_xml);


__END__

OUTPUT  :------->


IndustryType CurrencyCode CurrencyExponent1 CurrencyExponent2


xml :- >
<Request>
  <NewOrder1>
    <CurrencyCode>840</CurrencyCode>
    <CurrencyExponent2>2</CurrencyExponent2>
    <IndustryType>EC</IndustryType>
    <CurrencyExponent1>1</CurrencyExponent1>
  </NewOrder1>
</Request>

    [download]
    Thanks, Sham
[reply]
[d/l]
      For a start, there's one simple change that needs to be made. Replace: 
                                      {
                                %NewOrder_data,
                                }

      [download]
      with: 
                                      \%NewOrder_data,

      [download]
      Then, at least, $xmlDS will preserve the order that you assigned. (You can verify that with print Dumper($xmlDS), "\n";)

      However, the order gets lost in the final step when $request_xml is assigned its value. I couldn't find an easy way to deal with that ... perhaps XML::Simple also needs to 'use Tie::IxHash;' for this approach to work.

      Cheers,
      Rob
[reply]
[d/l]
[select]
        I couldn't find an easy way to deal with that

        But moritz had found the solution to that in an earlier post in this thread (moritz++). It's just a matter of replacing: 
            my $xs = new XML::Simple(keeproot => 1, SuppressEmpty => 1);

        [download]
        with: 
            my $xs = new XML::Simple(keeproot => 1, SuppressEmpty => 1, NoSort
+ => 1);

        [download]
        Here's the (final) amended version of the script: 
        use strict;
use XML::Simple;
use Data::Dumper;
use Tie::IxHash;

my     $Request_data = {};

tie my %NewOrder_data , 'Tie::IxHash';
tie my %r, 'Tie::IxHash';

my $request_xml = \%r;

 %NewOrder_data =  (        
                    'IndustryType'        => ['EC'], 
                    'CurrencyCode'        => ['840'],
                    'CurrencyExponent1'    => ['1'],
                    'CurrencyExponent2'    => ['2'],
                    );



my @keys = keys %NewOrder_data;
print "\n@keys\n";

    my $xmlDS = {
        Request => [
                {                
                NewOrder => [
                                \%NewOrder_data,
                            ],
                    }
            ],
        };

$request_xml = eval {
    my $xs = new XML::Simple(keeproot => 1, SuppressEmpty => 1, NoSort
+ => 1);
    $xs->XMLout($xmlDS);
    };

print STDERR "\n\nxml :- >\n" . Dumper($request_xml);

__END__
Outputs:

IndustryType CurrencyCode CurrencyExponent1 CurrencyExponent2


xml :- >
$VAR1 = '<Request>
  <NewOrder>
    <IndustryType>EC</IndustryType>
    <CurrencyCode>840</CurrencyCode>
    <CurrencyExponent1>1</CurrencyExponent1>
    <CurrencyExponent2>2</CurrencyExponent2>
  </NewOrder>
</Request>
';

        [download]
        Cheers,
        Rob
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom