Hi,

Is there a reason why you inherit AppMod to MyAppMod and create an object of AppMod at the same time ? If its just for overriding the subroutines, its not required. Consider the following.

    { package Animal;
      sub speak {
        my $class = shift;
        print "a $class goes ", $class->sound, "!\n"
      }
    }
    # Animal package from before
    { package Mouse;
      @ISA = qw(Animal);
      sub sound { "squeak" }
      sub speak {
        my $class = shift;
        print "a $class goes ", $class->sound, "!\n";
        print "[but you can barely hear it!]\n";
      }
    }

    Mouse->speak;
[download]

    a Mouse goes squeak!
    [but you can barely hear it!]
[download]

Cheers !

--VC

Note: Above example is from perlboot

Not sure if this is a useful answer, however you seem to be struggling with overriding methods so consider:

# file noname1.pm:
use strict;
use warnings;

package Hello;

sub new {
    my $type = shift; # Call as: Hello->new ();
    my $class = ref $type || $type;
    
    return bless {}, $class;
}


sub hi {
    my ($self, $tail) = @_;
    
    $tail ||= '';
    return 'Hello' . $tail;
}

1;

package World;

use noname1;
use base qw(Hello);

sub new {
    my $type = shift; # Call as: World->new ();
    my $class = ref $type || $type;
    
    return Hello::new ($class);
}


sub hi {
    my ($self, $tail) = @_;
    
    $tail ||= '';

    # Now call up to get base class work done
    return $self->Hello::hi (' World' . $tail);
}

1;


#file noname.pl:
use strict;
use warnings;
use noname1;

my $hi = World->new (); # Create derived class object

print $hi->hi ('. How goes it?'); # Call method on derived class objec
+t
[download]

Prints:

Hello World. How goes it?
[download]

my $class = ref $type || $type;

Nix that; you don't need it.

sub new {
    my $type = shift; # Call as: World->new ();
    my $class = ref $type || $type;
    
    return Hello::new ($class);
}
[download]

You don't need that either. Just delete the whole thing.

# Now call up to get base class work done
return $self->Hello::hi (' World' . $tail);
[download]

This is a lot better as:

return $self->SUPER::hi( ' World' . $tail );

... or even:

use SUPER;

# ...

    return $self->SUPER( ' World' . $tail );
[download]

This is helpful and thanks for the example!!. and yes that's what I was running into problem and understanding.
Thanks all!! it has been very helpful.