use DateTime;
my $date = DateTime->new( year   => 2007,
                          month  => 8,
                          day    => 25,
                          hour   => 23,
                          minute => 59,
                          second => 59,
                          time_zone => 'UTC',
                        );



print $date->ymd, "\t", $date->hms, "\n";

$date->add( hours => 36 );

print $date->ymd, "\t", $date->hms, "\n";
[download]

2007-08-25      23:59:59
2007-08-27      11:59:59
[download]

You should be able to accomplish this quite nicely with localtime and Time::Local.

As for whether the program has successfully run during the specified window, you'll need to implement some sort of queue to keep track of that. As jobs succeed, they should be removed from the queue... If they fail, they get pushed back onto the queue to be run with the other jobs for the next interval.

Update: BTW, what does Sat/36 actually mean? Is it this Saturday? or the next, etc? If you can change the spec, it's best to specify a date, as in 20070825/36 to eliminate any confusion.

Another solution is to use Time::ParseDate. Here is some source code that I tested:

use Time::ParseDate;

use strict;

my $input = shift || "";
my $day = undef;
my $hours = undef;

if ( $input =~ m!^(\w{3})/(\d+)! ) {
    $day = $1;
    $hours = $2;
} else {
    die( "Error: use an argument of ddd/hh (e.g. Sat/36)" );
}

# set up parse string to midnight (beginning) of desired day
my $parsestring = "next $day 00:00";

my $epoch = Time::ParseDate::parsedate( $parsestring );

$epoch += ( $hours * 3600 );

print( "     Epoch: $epoch\n" );
print( "  GMT Time: " . scalar( gmtime( $epoch ) ) . "\n" );
print( "Local Time: " . scalar( localtime( $epoch ) ) . "\n" );
[download]

When executed this outputs the following:

$ perl -w testparse.pl  Sat/36
     Epoch: 1188126000
  GMT Time: Sun Aug 26 11:00:00 2007
Local Time: Sun Aug 26 12:00:00 2007
[download]

Last note: think carefully whether you are doing times in the local timezone or GMT/UTC. (I was running this from London, UK, in summer time hence local time being one hour ahead of GMT).

use strict;
use Date::Manip;

my $arg = shift || "";

my $start;
my $end;

if (my ($day, $hours) = ($arg =~ m!^(\w{3})/(\d+)!)) {
    my $err;
    my $start = ParseDate($day);

    die "Bad day $day" unless $start;

    print UnixDate($start, "%u"), "\n";
    $end = DateCalc($start,"+ $hours hours", \$err);
    print UnixDate($end, "%u"), "\n";
} else {
    die( "Error: use an argument of dow/hours (e.g. Sat/36)" );
}
[download]