A particularly simple approach is:

use List::Util qw( shuffle );
my @picks = (shuffle 1..15)[0..4];
[download]

For picking a few numbers from a very long list, "rerolling" duplicates is probably the most efficient:

my @picks;
my %seen;
for (1..5) {                          # Five numbers
   my $pick = int(rand(15000)) + 1;   # in 1..15000.
   redo if $seen{$pick}++;
   push @picks, $pick;
}
[download]

Thanks guys for your replies.

Hi Ikegami, how would your "rerolling duplicates" method work if the l
+ist just thrice (not long enough) the total numbers to be drawn. I gu
+ess "shuffle" would be a better alternative then?

Thanks.
[download]

The shorter the list, the more rerolls would have to be done. shuffle will work quite well in most settings even with hundreds of items.

• Put your 15 integers into an array
• use shuffle from List::Util to shuffle the array
• Take the first 5 elements of the array using a slice

use List::Util 'shuffle';

my @numbers = 1 .. 15; # could be any list
@numbers = shuffle @numbers;
print "@numbers[0 .. 4]";
[download]

How about you just List::Util shuffle 1 to 15 and then splice the first 5:

#!/usr/bin/perl

use Data::Dumper;
use List::Util 'shuffle';

my @list = ( 1 .. 15 );
print Dumper( \@list );

my @shuffled = shuffle(@list);
print Dumper( \@shuffled );

my @five = splice( @shuffled, 0, 5 );
print Dumper( \@five );
[download]

my @a = ('a'..'z');
my $take = 5;
for (0..$take-1) {
  my $swap_with = $_ + rand(@a-$_);
  @a[$_,$swap_with] = @a[$swap_with,$_];
}
print join(',', @a[0..$take-1]), "\n";
[download]