First of all, it's a bad idea to use the variable names $a and $b in your code because they're special variables used by sort.

Secondly, you can write this:

foreach (@getcert) {
  $c = $_;
[download]

...as this:

foreach my $c (@getcert) {
[download]

To get your arrays into a hash, I'd use List::MoreUtils.

use List::MoreUtils qw( mesh );
my @users = qw( alice bob charlie );
my @ids   = qw( 123 456 789 );
my %id_of = mesh @users, @ids;
# now $id_of{ 'alice' } == 123
[download]

If you don't want to install List::MoreUtils, you could just paste in the source for mesh:

sub mesh (\@\@;\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\
+@\@\@) {
    my $max = -1;
    $max < $#$_  &&  ($max = $#$_)  for @_;

    map { my $ix = $_; map $_->[$ix], @_; } 0..$max; 
}
[download]

Lastly, if you haven't already, consider "use strict;use warnings;".

You could also use a hash slice to associate the two arrays:

my @users = qw( alice bob charlie );
my @ids   = qw( 123 456 789 );

my %id_of;
@id_of{@users} = @ids;  # hash slice


use Data::Dumper;
print Dumper(\%id_of);
[download]

Output

$VAR1 = {
          'alice' => '123',
          'charlie' => '789',
          'bob' => '456'
        };
[download]

You can utilize regexes for the task. The following is a recommendation.

use warnings;
use strict;

my $user_name_regex = qr/
    ~            # match the first ~
    ([^~]+)        # capture the characters as long as it is not a ~
/x;

my $smartcard_id_regex = qr/
    ~            # match the first ~
    ([^~@]+)    # capture the characters as long as it is not a ~ or @
/x;

@getuser = `dsquery user –name * -o samid –limit 1000`;

my @user_names = map {
    chomp;
    $_ =~ $user_name_regex;        # match and capture user name
    $1                            # return the capture;
} @getuser;

@getcert = `dsquery usern –name * -o upn –limit 1000`;

my @smartcard_ids = map {
    chomp;
    $_ =~ $smartcard_id_regex;    # match and capture smartcard id
    $1;                            # return the capture
} @getcert;
[download]

Here is a modified version of your code that builds a hash allowing lookup either by user or smartcard id. This is assuming $b = user and $e = smartcard id (your variable names don't provide a clue). Since the arrays are 1:1, the for loop is used to generate a common index into both arrays. For your own benefit (code maintenance), please consider:

• Not using single character variable names. Some have special meaning.
• Renaming your variables to something more meaningful.
• Using lexically scoped (my) variables.

use strict;
use warnings;

my %id_lookup;

my @getuser = `dsquery user -name * -o samid -limit 1000`;

my @getcert = `dsquery usern -name * -o upn -limit 1000`;

for (0 .. scalar @getuser -1){

    my $a = $getuser[$_];
    chomp $a;
    my $b = (split (/"/, $a))[1];

    my $c = $getcert[$_];
    chomp $c;
    my $d = (split (/"/, $c))[1];
    my $e = (split (/@/, $d))[0];

    $id_lookup{$b} = $e;

    # this line adds reverse lookup, if desired
    $id_lookup{$e} = $b;
}
[download]