Monks,

I currently looking at Data::Validator::Item to verify that the input data my application receives is according to specification. I am concerned about that the documentation says "alpha" and the module hasn't been updated since Jan 2003.

I wonder what (modules) the enlightened monks use to perform data validation.

use strict;
use warnings;

use Date::Calc qw(check_date);
use Data::Validator::Item;

my @variables = qw (FIRSTNAME GENDER BIRTHDATE_DDMMYYYY);

my %dictionary = ();
foreach my $variable (@variables) {
  $dictionary{$variable} = Data::Validator::Item->new();
  $dictionary{$variable}->name($variable);
  $dictionary{$variable}->missing(q{});    # default blank
}

my $gender_coderef = sub {
  my $input     = shift;
  my %transform = (
    1 => 'M',
    2 => 'F',
    3 => 'U',
  );
  return $transform{$input};
};

my $ddmmyyyy_coderef = sub {
  my $ddmmyyyy = shift;
  $ddmmyyyy =~ /^(\d{2})(\d{2})(\d{4})$/;
  my ($year, $month, $day) = ($3, $2, $1);
  return check_date($year, $month, $day);
};

$dictionary{GENDER}->transform($gender_coderef);
$dictionary{GENDER}->values([ 1, 2, 3 ]);    # Valid values *before* t
+ransform

$dictionary{BIRTHDATE_DDMMYYYY}->verify($ddmmyyyy_coderef);

# ------ main ------
my $line = 0;
while (<DATA>) {
  $line++;
  chomp;
  my ($index, $error) = (0, 0);
  my @fields = split(q{;}, $_);
  my @output = ();
  foreach my $elem (@fields) {

    if ($dictionary{ $variables[$index] }->validate($elem) != 1) {
      print "Error on line " . $line
        . " in column "
        . $variables[$index]
        . " value:"
        . $elem;
      $error++;
    } else {
      push @output, $dictionary{ $variables[$index] }->put($elem);
    }
    $index++;
  }

  # Print lines without errors only
  print join(q{;}, @output) if (!$error);
}

__DATA__
Kermit;1;21131986
Swedish Chef;3;21031959
Miss Piggy;4;07111987
[download]

Output:

$ perl -wl dvi.pl
Error on line 1 in column BIRTHDATE_DDMMYYYY value:21131986
Swedish Chef;U;21031959
Error on line 3 in column GENDER value:4
[download]