Within the limitations of doubles to represent large numbers accurately, you can do this by breaking the number into hi and lo integers, converting them separately, and concatenating the results:

$huge = 1024**4;;
$lo = $huge % 2**32;;
$hi = int( $huge / 2**32 );;

printf "%b%032b\n", $hi, $lo;;
10000000000000000000000000000000000000000
[download]

Otherwise take a look at the bigint pragma and Math::BigInt.

You could do something like

#!/usr/bin/perl

use bigint;

sub split32 {
    my $v = shift;
    my $n = shift;
    my $mask = 0xffffffff;
    my @b32;
    for (1..$n) {
        unshift @b32, $v & $mask;
        $v >>= 32;
    }
    return @b32;
}

my $n = 2;    # n x 32-bit

my $v = 1024;
for (1..6) {
    print unpack("B*", pack("N$n", split32($v, $n) )), "\n";
    $v *= 1024;
}
[download]

Prints

0000000000000000000000000000000000000000000000000000010000000000
0000000000000000000000000000000000000000000100000000000000000000
0000000000000000000000000000000001000000000000000000000000000000
0000000000000000000000010000000000000000000000000000000000000000
0000000000000100000000000000000000000000000000000000000000000000
0001000000000000000000000000000000000000000000000000000000000000
[download]

I've set the width to 64 bit in the example (to avoid line wrapping...), but in principle, you can also use larger widths, e.g. $n = 8 for 256 bits. Also, $v can of course be any integer number, and must not necessarily be a power of 1024.

Update: BTW, don't indiscriminately enable bigint for your entire program... it can slow down things considerably! Limit its scope to where you really need it — by putting extra blocks around those sections:

{
    use bigint;

    # code that needs it...
}

# other code...
[download]

#!/usr/bin/perl -w

use strict;
use Math::BigInt;

my $number = '38562959738576293875632496';
my $n = Math::BigInt->new($number);
print $n->as_bin(), "\n";
[download]

If you are just playing with powers 1024, it might be good enough to know that the binary representation for 1024 is a "1" followed by 10 zeros. That is:

$binary_string = "1" . "0" x 10;
print "$binary_string\n"
[download]

$power = 4;
$binary_string = "1" . "0" x (10 * $power);  # parens required
print "$binary_string\n"
[download]

Use tilly's Math::Fleximal. And if you are curious how it accomplishes it, then read the source code (it implements its own whatever-number-base "big int" library).