use Data::Dumper;

my %colorhash = ( CCgray  => [ "0","0","0" ],
                  CCwhite => [ "1","0","0" ],
                  CCgrey  => [ "0","2","0" ],
                  CCBlue  => [ "0","0","3", ] );

my @light2dark = sort numsort (keys %colorhash);

print Dumper \@light2dark;

sub numsort {
    $colorhash{$a}[0] <=> $colorhash{$b}[0]
 or $colorhash{$a}[1] <=> $colorhash{$b}[1]
 or $colorhash{$a}[2] <=> $colorhash{$b}[2];
}
[download]

Output:

$VAR1 = [
          'CCgray',
          'CCBlue',
          'CCgrey',
          'CCwhite'
        ];
[download]

oops, but it still does not change the order based on the value. There is not change in the hash order.

The hash order is always random, and has nothing to do with the order in which that hash was created.

Compare the following snippet with the original:

use Data::Dumper;

my %colorhash = ( CCgray  => [ "0","0","0" ],
                  CCwhite => [ "1","0","0" ],
                  CCgrey  => [ "0","2","0" ],
                  CCBlue  => [ "0","0","3", ] );

my @light2dark = keys %colorhash;

print Dumper \@light2dark;
[download]

PS Have you enclosed your original program within <code>...</code> tags yet?

I'm not sure if this is homework, but you certainly won't get that code to work.

#!/usr/bin/perl
use warnings;
use strict;

my %colorhash = ( CCgray => ["0","0","0"],
          CCwhite => ["1","0","0"],
          CCgrey => ["0","2","0"],
          CCBlue => ["0","0","3"]);

foreach my $colorname (keys %colorhash) {
  for my $i (0.. $#{ $colorhash{$colorname} } ) { 
    print "$i = $colorhash{$colorname}[$i] "; 
  }
  print "\n"; 
} 

my @light2dark = sort numsort (keys %colorhash); 

sub numsort { 
  $colorhash{$a}[0] <=> $colorhash{$b}[0] 
  or $colorhash{$a}[1] <=> $colorhash{$b}[1] 
  or $colorhash{$a}[2] <=> $colorhash{$b}[2]
}
[download]

Responding to my own post.

First rule:

use warnings;
use strict;

That's the annoying but seemingly impossible to avoid mantra of a good perl developer. Exclude them at your own risk, and only when you know why you are doing so. You really needed to find out where the code just would not work.

As previously remarked, your value assignment strategy does not do what you think. Since '=>' is just a sophisticated comma, your hash assignment is interpreted as:

%colorhash = (CCgray => "0",
              "0" => "0",
              CCwhite => "1",
              "0" => "0",
etc.
[download]

I think you can see where this is going. Anonymous arrays are constructed within brackets.

As mentioned before, the quotes around clearly numeric values are unnecessary.

Next, for some reason, your example has:

$colorhash{$colorname}$i
[download]

Obviously, the array brackets are missing.

You should also research the usage of 'sort'. You defined a sort evaluation call, but didn't call sort to use it.

#!/usr/bin/perl
use warnings;
use strict;

my %colorhash = ( CCgray  =>  ["0","0","0"], 
                  CCwhite =>  ["1","0","0"], 
                  CCgrey  =>  ["0","2","0"], 
                  CCBlue  =>  ["0","0","3"], ); 

 print "Original order of data:\n\n";
foreach my $colorname (keys %colorhash) { 
    printf "For key %-7s : ",$colorname;
    for my $i (0.. $#{ $colorhash{$colorname} } ){ 
         print "element[", $i,"] = $colorhash{$colorname}[$i] "; 
    } 
    print "\n"; 
} 
print "\n\n";
my @light2dark = sort lightsort (keys %colorhash); 
my @dark2light = sort  darksort (keys %colorhash); 

print "Order, dark  is ",join(',',@dark2light), ".\n";
print "Order, light is ",join(',',@light2dark), ".\n";

sub darksort { 
    $colorhash{$b}[0] <=> $colorhash{$a}[0] or 
    $colorhash{$b}[1] <=> $colorhash{$a}[1] or 
    $colorhash{$b}[2] <=> $colorhash{$a}[2] 
} 

sub lightsort { 
    $colorhash{$a}[0] <=> $colorhash{$b}[0] or 
    $colorhash{$a}[1] <=> $colorhash{$b}[1] or 
    $colorhash{$a}[2] <=> $colorhash{$b}[2] 
}
[download]

C:\Code>perl color-sort.pl
Original order of data:

For key CCBlue  : element[0] = 0 element[1] = 0 element[2] = 3
For key CCgray  : element[0] = 0 element[1] = 0 element[2] = 0
For key CCgrey  : element[0] = 0 element[1] = 2 element[2] = 0
For key CCwhite : element[0] = 1 element[1] = 0 element[2] = 0


Order, dark  is CCwhite,CCgrey,CCBlue,CCgray.
Order, light is CCgray,CCBlue,CCgrey,CCwhite.
[download]

my %colorhash = ( CCgray => "0","0","0", CCwhite => "1","0","0", CCgrey => "0","2","0", CCBlue => "0","0","3", );

This isn't what you expect. It is the same as

my %colorhash = ( 
  CCgray  => "0",
  "0"     => "0",
  CCwhite => "1",
  "0"     => "0", 
  CCgrey  => "0",
  "2"     => "0", 
  CCBlue  => "0",
  "0"     => "3",
);
[download]

while you surely want

my %colorhash = ( 
  CCgray  => [ "0","0","0" ], 
  CCwhite => [ "1","0","0" ],
  CCgrey  => [ "0","2","0" ],
  CCBlue  => [ "0","0","3" ],
);
[download]

See perlref and perlreftut.

Ah, and another thing: you don't need quotes around your numbers. The above is better written as

my %colorhash = ( 
  CCgray  => [ 0, 0, 0 ], 
  CCwhite => [ 1, 0, 0 ],
  CCgrey  => [ 0, 2, 0 ],
  CCBlue  => [ 0, 0, 3 ],
);
[download]

_($_=" "x(1<<5)."?\n".q·/)Oo.  G°\        /
                              /\_¯/(q    /
----------------------------  \__(m.====·.(_("always off the crowd"))."·
");sub _{s./.($e="'Itrs `mnsgdq Gdbj O`qkdq")=~y/"-y/#-z/;$e.e && print}