You might have some that read

zone "10.in-addr.arpa" {
    type forward;
    forwarders {
        10.1.2.3;
        10.1.2.4;
        10.1.2.5;
    };
};
[download]

There are, as always, many ways to do it - one:

my $comment = 0;
my $block   = 0;
while (<HAN>) {
    /^zone\s+"$targetdomain"/ and $comment++;
    if($comment) {
        $block += () = /(\{)/g;        # add the number of { matches t
+o $block
        s!^!// ! if $comment && $block;
        $block -= () = /(\})/g;        # substract the number of } mat
+ches
        $comment = 0 unless $block;
    }   
    print;
}
[download]

That will work only if the opening curly after a zone declaration is on the same line.

BTW, you need a semicolon after every closing curly in your zone file ( }; ).

_($_=" "x(1<<5)."?\n".q·/)Oo.  G°\        /
                              /\_¯/(q    /
----------------------------  \__(m.====·.(_("always off the crowd"))."·
");sub _{s./.($e="'Itrs `mnsgdq Gdbj O`qkdq")=~y/"-y/#-z/;$e.e && print}

thanks for you replay :)
but i want to know what are the function of two variables $comment ,, $block
please explain me carefully cuz iam newbie :) .
and if i want to instead of printing the commented zone in the shell
i want how to make that inside the file affecting the matched zone only
and iam thankful for you

• $comment is a switch, which is turned on when the sought zone is found, and turned of if the associated block is processed. If $comment is true (i.e. not '0' and not ''), the current line is commented out.
• $block is a counter for the curly bracket level. It is increased with each opening bracket, and decreased with each closed bracket. If the last closing bracket of the zone block is found, it is zero, we are done and can unset $comment.

The empty () in the assignments force list context on the right hand side (global match), so we get all matches; the left hand side is a scalar ($block), so we get the count of those matches: a list evaluated in scalar context returns the number of elements of the list.

To edit the file, it makes sense to backup the file and write it:

#!/usr/bin/perl -w 

use strict;

print " please enter the domain name: ";

my  $targetdomain = <STDIN>;

chomp $targetdomain;

my  $file = "/home/blackice/hello";

rename $file, "$file.bak" or die "Can't rename file '$file': $!\n";

open my $in, '<', "$file.bak" or die "Can't read file '$file': $!\n";
open my $out, '>', $file or die "Can't write file '$file': $!\n";

my $comment = 0;
my $block   = 0;

while(<$in>) {
    if (/^zone\s+"$targetdomain"/) {
        $comment++;
        $block += () = /(\{)/g;
        print $out '// '.$_; next;
    }
    if($comment) {
        $block += () = /(\{)/g;
        s!^!// ! if $comment or $block;
        $block -= () = /(\})/g;
        $comment = 0 unless $block;
    }
    print $out $_;
}
[download]

This version works also with zone entries where the opening curly is on the next line:

zone "foo"
{
    type "master";
    ...
};
[download]

--shmem

_($_=" "x(1<<5)."?\n".q·/)Oo.  G°\        /
                              /\_¯/(q    /
----------------------------  \__(m.====·.(_("always off the crowd"))."·
");sub _{s./.($e="'Itrs `mnsgdq Gdbj O`qkdq")=~y/"-y/#-z/;$e.e && print}

For a start you have to create a new instance of the file. Perl helps by facilitating inplace editing of files using @ARGV, $^I and while (<>) {...} magic.

The other less common element Perl used in this code is the scalar context range operator ...

use strict;
use warnings;

open OUTFILE, '>', 'delme.txt';
print OUTFILE <<TEXT;
zone "dontchangethisdomain.com" {
type master;
file "/somepath/to/dontchangethisdomain.com";
notify yes;
}
zone "mydomain.com" {
type master;
file "/path/to/zone/mydomain.com";
notify yes;
}
zone "leavethisalonetoo.com" {
type master;
file "/other/path/to/leavethisalonetoo.com";
notify yes;
}
TEXT
close OUTFILE;

my $targetdomain = 'mydomain.com';

@ARGV = ('delme.txt');
$^I = '.bak';

while (<>) {
    print "#" if m/^zone "\Q$targetdomain\E" {/ .. m/^}/;
    print;
}
[download]

Generates delme.txt containing:

zone "dontchangethisdomain.com" {
type master;
file "/somepath/to/dontchangethisdomain.com";
notify yes;
}
#zone "mydomain.com" {
#type master;
#file "/path/to/zone/mydomain.com";
#notify yes;
#}
zone "leavethisalonetoo.com" {
type master;
file "/other/path/to/leavethisalonetoo.com";
notify yes;
}
[download]

thanks for your help
put there isn't any way to edit in the file locally without making instance ? .

You have to insert characters. Think about what that entails in terms of manipulating the file image on the hard disk. Every character after the inserted character has to be moved.

There are modules like Tie::File which hide the details from you and expend a great amount of effort to make the process efficient, but at the end of the day every character in the file after the first character that is inserted has to be rewritten.

---

Perl is environmentally friendly - it saves trees

#!/usr/bin/perl

use strict;

( @ARGV == 2 and -f $ARGV[0] )
    or die "Usage: $0  input.file  domain.to.comment.out\n";

my ( $in_file, $rem_domain ) = @ARGV;
open IN, "<", $in_file or die "$in_file: $!";
open OUT, ">", "$in_file.new" or die "$in_file.new: $!";

$/ = "\n}";     # input record separator is line-initial "}"

while (<IN>) {               # $_  contains a whole zone block
    if (/\W$rem_domain\W/) {
        s/^/#/;              # add initial comment to block
        s/\n/\n#/g;          # add comment after each "\n"
    }
    print OUT;
}
[download]

(It could happen that someone hits the "Enter" key too soon, and comments all zone blocks that match an unintended substring.) BTW, this approach is also an easy way to uncomment a chosen block, in case you ever need that sort of tool.

(update: forgot mention: look up $/ in perlvar)