#!/usr/bin/perl
use strict;
use warnings;

my @names;

while (<DATA>){
    chomp;
    m/^(\d+)\s+(.*)/;
    push @names, [$1, $2];
}

@names = sort { $a->[1] cmp $b->[1] } @names;

for (@names){
    print "$_->[0] $_->[1]\n";
}

__DATA__
1 Charlie
1 Edward
2 Bob
2 Alfred
3 Barry
[download]

    m/^(\d+)\s+(.*)/;
    push @names, [$1, $2];
[download]

Don't use $1 without testing whether the match succeeded or not. If you expect the match to always succeed, at least add an "or die". Failure to do so will give you a "stale" $1 when you least expect it.

-- Randal L. Schwartz, Perl hacker

works great, Thanks!

  # open the file
  open my $fh, '<', 'myfile.dat' or die "$!"

  # translate the data into a 2D array
  my @rows = map [ split /\s+/ ],  <$fh>;

  # sort on any column
  my @sorted = sort { $a->[1] cmp $b->[1] } @rows;

  # print the result
  print "@$_\n" for @sorted;
[download]

I think this will do it here. As in Re: How to sort? noted, this doesn't look like a real "csv" data file.

Regards

mwa

use Sort::Key qw(keysort);

my @data = <>;
my @sorted = keysort { (split /\s+/, $_, 2)[1] } @data;
print @sorted;
[download]

use strict;
use DBI;

my $dbh = DBI->connect('dbi:AnyData:');
$dbh->func(
    'test', 'CSV', 'test.csv',
    {sep_char  => ',',
     eol       => "\n",
     col_names => 'number,name',
    },
    'ad_catalog',
);

my $sth = $dbh->prepare("SELECT number, name FROM test ORDER BY name")
+;
$sth->execute();
while ( my $row = $sth->fetch ) {
    print "@$row\n";
}
[download]

2  Alfred
3  Barry
2  Bob
1  Charlie
1  Edward
[download]

That assumes names are unique.

use strict;
use warnings;

print map { $_->[0] . "\n"; } sort { $a->[1] cmp $b->[1] } map { chomp
+; [$_, /\d+\s+([a-zA-Z]+)/]; } <DATA>;

__DATA__
1 Charlie
1 Edward
2 Bob
2 Alfred
3 Barry
[download]

exec qq( sort -k 2 "$ARGV[0]" )
[download]

(Doesn't work on all platforms. ;-)

If those numbers are always one-digit, then you can simply sort by the substring starting position 3 (1 based), and don't even bother to split or regexp.