split -l 500 file.txt
[download]

If you want to use perl, you can make use of the special variable (INPUT_LINE_NUMBER): $.

In Perl,

#!/usr/bin/perl

# Usage:
#   split.pl numlines file [file [file [...]]]

use strict;
use warnings;

my $SPLIT_POINT = shift(@ARGV);

my $fh;
my $part = 'aaaa';
while (<>) {
   if ($. % $SPLIT_POINT == 1) {
      # Time to start a new output file.
      undef $fh;
   }

   if (!defined($fh)) {
      # Or whatever
      my ($file, $ext) = $ARGV =~ /^(.*?)((?:\.\w*)?)\z/s;
      $file .= sprintf('[%s]%s', $part++, $ext);

      open($fh, '>', $file)
         or die("Unable to create part file \"$file\": $!\n");
   }

   print $fh $_;

   if (eof(ARGV)) {
      # Finished processing one input file.
      undef $fh;       # Start a new output file.
      $part = 'aaaa';  # Reset part number.
      close(ARGV);     # Reset $.
   }
}
[download]

Thank you the code. This will be a big help.

Just replace $. % $SPLIT_POINT == 1 with the split condition in the code I provided.