/x only impacts how the regex is parsed. It can't impact how the string is parsed. \u impacts how the string is generated. The string has to be parsed and generated before the resulting string can be passed to the regex engine which then parses the string as a regex. And it is clear that /x can't impact the parsing of the string because the string has to be parsed before Perl can even see the /x.

If we fix your "bug", then we should also have to fix this to work:

"Y" =~ /\u(?x: y)/
    or  die "\\u and (?x: ) don't cooperate";
[download]

So this is a bit of a restatement of other replies, perhaps, but \u isn't a regex construct, so it isn't impacted by regex flags.

You'll also note other things that aren't impacted by /x:

/$foo bar[5]/x; # Not the same as /$foobar[5]/
/\ u2/x;        # Not the same as /\u2/, obviously
/\01 2/x;       # Not the same as /\012/
/$hash{a Key}/x;# Not the same as /$hash{aKey}/
[download]

You can also tell that /x impacts regex parsing not string parsing because:

#!/usr/bin/perl -w
my $x= " b c ";
print for "abcd" =~ /$x/xg;
# prints "bc"
[download]

And one other way to see that \u isn't a regex thingy:

print "($1)($2)\n"
    while  "fFFggGGGG" =~ /([a-z]+)\U(\1*)/g;
print "---\n";
print "($1)($2)\n"
    while  "fFFggGGGG" =~ /([a-z]+)\U(\1*g)/g;
__END__
Prints:
(f)()
(gg)()
---
(gg)(G)
[download]