Huh. Everyone wants to type a lot. :)

You're trying to create a "Hash of Arrays". Check out perldsc, the "Perl Data Structure Cookbook" for lots of examples. Here's how I created it from your example data:

#!/usr/bin/perl
use strict;
use warnings;

my %hash = ();
my $key;

while( <DATA> )
    {
    chomp;
    
    if(    /^(\S.*)/    ) { $key = $1 }
    elsif( /^\s+(\S.*)/ ) { push @{ $hash{$key} }, $1 }
    elsif( /^\s*$/      ) { next; }
    }

use Data::Dumper;
print Dumper( \%hash );

__DATA__
Honda
 Civic
 Accord

Toyota
 Camry
 Corolla
 Tundra

Nissan
 Maxima
[download]

You're already halfway to YAML . . .

my $ref = YAML::Syck::Load( <<'EOT' );
---
Honda:
  - Civic
  - Accord
Toyota:
  - Camry
  - Corolla
  - Tundra
Nissan:
  - Maxima
EOT
[download]

$ref->{car}->{Honda}->[0]="Civic";
$ref->{car}->{Honda}->[1]="Accord";
$ref->{car}->{Toyota}->[0]="Camry";
$ref->{car}->{Toyota}->[1]="Tundra";
$ref->{car}->{Toyota}->[2]="Corolla";
[download]

Several things there that can be improved on. ;)

The first is that $ref is a hash reference. More likely you simply want a hash:

my %ref;
[download]

Perl allows some syntactic sugar that removes all those -> so you can write:

$ref{car}{Toyota}[2]="Corolla";
[download]

However if you want to initialize a hash then you can:

my %ref = (
    car => {
        Honda => [qw(Civic Accord)],
        Toyota => [qw(Camry Tundra Corolla)],
        }
    );
[download]

taking advantage of qw so that the car names don't require quoting.

---

Perl is environmentally friendly - it saves trees

You seem to have an extra level, a hash with a single key.

$ref->{Honda}->[0]="Civic";
$ref->{Honda}->[1]="Accord";
$ref->{Toyota}->[0]="Camry";
$ref->{Toyota}->[1]="Tundra";
$ref->{Toyota}->[2]="Corolla";
[download]

By the way, the arrow between indexes can be omitted.

$ref->{Honda}[0]="Civic";
$ref->{Honda}[1]="Accord";
$ref->{Toyota}[0]="Camry";
$ref->{Toyota}[1]="Tundra";
$ref->{Toyota}[2]="Corolla";
[download]

It seems odd to refer to array indexes using a constant.

$ref->{Honda}  = [ qw( Civic Accord         ) ];
$ref->{Toyota} = [ qw( Camry Tundra Corolla ) ];
[download]

Or if you were in a loop,

push @{$ref->{Honda}}, 'Civic';
push @{$ref->{Honda}}, 'Accord';
push @{$ref->{Toyota}}, 'Camry';
push @{$ref->{Toyota}}, 'Tundra';
push @{$ref->{Toyota}}, 'Corolla';
[download]

#!/usr/bin/perl
use strict;
use warnings;

my %hash;
my $make;

while( <DATA> )
    {
    chomp;
   
    if(    /^(\S.*)/    ) { $make = $1 }
    elsif( /^\s+(\S.*)/ ) { $hash{$make}{$1} = 1 }
    elsif( /^\s*$/      ) { next; }
    }

use Data::Dumper;
print Dumper( \%hash );

# Valid - prints "Valid..."
my ($make1, $model1) = qw(Nissan Maxima);
print "Valid $make1 model1\n" if $hash{$make1}{$model1};

# Not valid - doesn't print
my ($make2, $model2) = qw(Toyota Mustang);
print "Valid $make2 model2\n" if $hash{$make2}{$model2};

# Valid - prints "Valid..."
my $make3 = "Ford";
print "Valid $make3\n" if $hash{$make3};

__DATA__
Honda
 Civic
 Accord

Toyota
 Camry
 Corolla
 Tundra

Nissan
 Maxima
[download]

elsif( /^\s+(\S.*)/ ) { $hash{$make}{$1} = 1 }
[download]

elsif( /^\s+(\S.*)/ ) { $hash{$make,$1} = 1 }
[download]

print "Valid $make1 $model1\n" if $hash{$make1,$model1};
[download]

Oh it's not the OP's taste in cars. That list was supplied by the school teacher.

---

Perl is environmentally friendly - it saves trees