There are several options, perhaps the easiest is to write to a temporary file first, and then move this to the location of the old file.

Or you could use Tie::File - that changes the file that it's tied to.

$ perl -i.bak -ape '/^newyork/ and s/153600/7878787878/' test.cfg
[download]

hen i print the line the value is changed but when i vi the file it still has the old value..any help of what's going wrong

As moritz said, you are just "reading" a file. Thats it. BUT: Perl provides a special way to modify lines of files via its command line interface. The following command would read the file line by line and change the sequence "newyork 1536000" to the desired output - which is written to a temporary file and renamed to the original file name afterwards. The original file will be kept and named test.cfg.bak (this is what the -i option does).

 Unix/Linux:
 perl -i.bak -pe 's/(newyork\s+)1536000/${1}7878787878/' test.cfg

 Windows:
 perl -i.bak -pe "s/(newyork\s+)1536000/${1}7878787878/" test.cfg
[download]

Regards

mwa

Hopefully the others have addressed your issue. I'd like to comment on

open FILE, "+< test.cfg" || die "Cannot open file\n" ;
[download]

It's the same thing as

open FILE, ("+< test.cfg" || die "Cannot open file\n") ;
[download]

You want

open FILE, "+< test.cfg" or die "Cannot open file\n";
[download]

General rule: If you don't care about the return vakue of the OR, you want or instead of ||.

Better yet, use a lexical file handle, use the 3-arg form of open, and include the cause of the error ($!) in the error message.

open my $fh, '+<', 'test.cfg" or die "Cannot open file: $!\n";
[download]

Tie::File may suit your problem but I think there was a thread or something in the CB a few days ago to the effect that every change to the array tied to your file results in a complete file write as writes in Tie::File can't be deferred. This may cause performance problems if your module is modifying many lines in a large file.

Here is a simple example using your data.

# cat test.cfg
newyork 1536000 13 56
california 1536000 67 45
London 456
newyork 1536000 78 87
$ cat spw649958
#!/usr/bin/perl
#
use strict;
use warnings;

use Tie::File;

my $file = q{test.cfg};
tie my @lines, q{Tie::File}, $file
   or die qq{tie: $file: $!\n};

foreach my $line ( @lines )
{
    next unless $line =~ m{^newyork};
    $line =~ s{1536000}{7878787878};
}

untie @lines
   or die qq{untie: $file: $!\n};
$ ./spw649958
$ cat test.cfg
newyork 7878787878 13 56
california 1536000 67 45
London 456
newyork 7878787878 78 87
$
[download]

I hope this is of use.

Cheers,

JohnGG

think i have to use tie::file.I went thru the perl doc ..but its not clear how to use it .could you give me a simple eg how to use it

for Tie::File, you have look at the file's lines as if they would be like "array elements", - by changing them you'd change the file. What did you try so far - what didn't work?

BTW, this problem looks rather simple, so you could employ your own file handling - sth. like this:

 ...
 my ($fnNew, $fnOld) = ('test.cfg', 'test.cfg.bak');
 rename $fnNew, $fnOld or die "can't rename $fnNew, $!";

 open my $fin,  '<', $fnOld || die "$fnOld - $!";
 open my $fout, '>', $fnNew || die "$fnNew - $!";
 
 while( my $line = <$fin> ) {
    $line =~ s/(newyork\s+)1536000/${1}7878787878/;
    print $fout $line
 }
 close $fin; close $fout;
 ...
[download]

This would do basically the same as the 'one-liner' in another example already given.

Regards

mwa