Well, with far less code, you could do the following:

my $string = q("one","two","three");
my @array = split( /"(?:,")?/, $string );
[download]

This will, however, create an empty element at the beginning of the list (the stuff before the opening quote of "one"). You could remove it afterwards with shift @array.

You could attempt to get rid of that extra element with a negative look-behind assertion:

 my @array = split( /(?<!^)"(?:,")?/, $string );
[download]

But that has the undesirable property of returning a string equivalent to:

 my @array = qw( "one two three );
[download]

Again, this is trivial to fix:

   $array[0] =~ s/^"/;
[download]

But, as you can see, when what appears as very simple code turns out to require some weird make-work code to solve the "almost-there" case, there's something wrong. This is what is known as code smell. I think what you really want is to load a module, such as Text::CSV_XS (or Text::CSV), and be done with it.

Even if you think it's overkill in this instance, it doesn't cost you much to learn how to use it. In the long run, you will have learnt how to use it in a simple scenario, and that will pay off later when you have some much hairier CSV problems, and you might risk trying to extend this code a bit more, rather than using a proven module... and that's when you'll pay the full price of not having learnt it now when it was easy.

If the strings don't contain commas then you could:

my $string = q("one","two","three");
my @array = map {s/^['"](.*)['"]$/$1/ ? $1 : $_} split ',', $string;

print "@array";
[download]

Prints:

one two three
[download]

Text::Balanced has some general-purpose parsing routines for extracting quoted text. Regexp::Common has some regexes for matching quoted text, while handling escaped quotes. You would then have to write your own little parser to keep applying the regex.

I realize you asked to do this without the aid of modules. However, the task is much easier with one of these, and for non-trivial cases reinventing your own wheel is not advisable.

Your format seems to be simple quoted csv. So you can use one of the csv-modules from cpan to parse the string into fileds.

I would suggest Text::CSV. Have a look at the example that comes with the documentation. It is not shorter than your regex-split sollution - but more stable.

Update: grammar fix

use strict;
use warnings;

my $str = q{"one","two", "not three" , ' four',"five " };

my @arr = $str =~ m
   {(?x)
       (?<=['"])
       ([^,'"]+)
       (?=['"])
   }g;

print qq{-->$_<--\n} for @arr;
[download]

Here's the output.

-->one<--
-->two<--
-->not three<--
--> four<--
-->five <--
[download]

This method is going to fall down pretty quickly as your data gets more complex and I agree with others who have suggested some sort of CSV module to tackle the problem.

Cheers,

JohnGG

#!/usr/bin/perl
use warnings;
use strict;

my $str = q("string with a comma,","and some spaces", "three");
my @array;
eval <<"EVILEVAL";
\@array = ( $str );
EVILEVAL

print "ELT: $_\n" for @array;
[download]

More seriously, the CSV approaches people have mentioned are probably the way to go.

Actually, I did do this as a temporary fix so I could get on with the rest of the project. Here's my penance:

1. I will not execute my data.
2. I will not execute my data.
   ...
   ...
   ...
100. I will not execute my data.
[download]

Awesome. I hope you one day repent, but we all know there is nothing so permanent as a temporary fix.

More seriously, make sure your aren't getting your strings from a place where someone might be able to inject any code.

As I'm sure you know, this is like SQL injection but only more fun since you have a whole perl interpreter to play with.

$var1 = q("one","two","three",'four');
for $var2 ( split(/,/, $var1) )
{
    $var2 =~ s/"|'//g;
    push(@arr1, $var2);
}
print "@arr1\n";

one two three four
[download]

Cheers
Chris