#!/usr/bin/env perl

use warnings;
use strict;
my $str = 'aabceezazerrfde';
my %vals = (
    'a' => 7,
    'e' => 2,
    'z' => 26
);
my @chars = split //, $str;
my $tot = 0;
for (@chars) {
    if (exists $vals{$_}) {$tot += $vals{$_}}
}
print "total = $tot\n";
[download]

Starting with your data, I get a solution similar to toolic's, but I use List::Util and List::MoreUtils.

use List::Util qw( sum );
use List::MoreUtils qw( zip );

my $str = "aabceezazerrfde";
my $wanted = "aez";
my @values = (7,2,26);

my @wanted = split //, $wanted;
my %value_of = zip @wanted, @values;
my $tot = sum map { $value_of{$_} || 0 } split //, $str;
[download]

Note that if you use warnings (as you should), this will puke up "Use of uninitialized value in subroutine entry" for every letter in $str that is not in $wanted, but otherwise it works fine.

Update: With a small change, no more warnings.

use strict; 
my $str = "aabceezazerrfde";
my %values = ('a' => 7, 'e' => 2, 'z' => 26);
my $total = 0;

foreach(split '',$str){
    if($values{$_}){
        $total += $values{$_};
    }
}
print "Total: $total";
[download]

This seems more Perl-style: use some more resources to make your life easier... not sure it's always a good approach but hey, this is Perl :)

Hope this helps!

for, map, grep and split provide a little synergy here:

use strict;
use warnings;

my $str = "aabceezazerrfde";
my %wanted = (a => 7, e => 2, z => 26);
my $tot = 0;
my $counter = 0;

$tot += $_ for map {++$counter; $wanted{$_}} grep {exists $wanted{$_}}
+ split //, $str;
print "Found $counter letters totaling $tot\n";
[download]

Prints:

Found 9 letters totaling 81
[download]

Update: s/,/;/ in map - bug fix, thanks toolic.

Why does this not result in a total of 81?

The letter "a" appears 3 times: 3x7=21

The letter "e" appears 4 times: 4x2=8

The letter "z" appears 2 times: 2x26=52

21+8+52=81, not 126.

Because of a bug ;). map {++$counter, $wanted{$_}} should have been map {++$counter; $wanted{$_}} (note the s/,/;/).

---

Perl is environmentally friendly - it saves trees

perl -wMstrict -e
"my $str = 'aabceezazerrfde';  my %values = qw(a 7  e 2  z 26);
print scalar map { (0) x $values{$_} } grep exists $values{$_}, split 
+'', $str;"
81
[download]

I couldn't resist posting a solution that doesn't use split, even if it uses string eval instead:

use strict;
use warnings;

my $str = "aabceezazerrfde";
my %vals = ( a => 7, e => 2, z => 26 );

my $total = 0;

while( my ( $char, $val ) = each %vals )
{
    my $count = eval "qw($str) =~ tr/$char//" or die $@;
    my $charval = $count * $val;
    $total += $charval;
    print "Found [$char] $count times ($count * $val = $charval)\n";
}

print "Total = $total\n";
[download]

Found [e] 4 times (4 * 2 = 8)
Found [a] 3 times (3 * 7 = 21)
Found [z] 2 times (2 * 26 = 52)
Total = 81
[download]

I'm late on this but here's a version I liked, for brevity:

use strict;
use warnings;

my $str = "aabceezazerrfde";
my %wanted = (a => 7, e => 2, z => 26);
my $tot = 0;
$wanted{$_} && ($tot +=  $wanted{$_}) for (split //, $str);
print "Total $tot\n";
[download]

Better in some circumstances might be:

exists $wanted{$_} && ($tot +=  $wanted{$_}) for (split //, $str);

but I don't think it matters in this case. I discussed mixing "for" and "if" in one line with moritz and shmem recently, and I rather like it, though someone said it was too much logic for one line...

 ($tot +=  $wanted{$_})  if $wanted{$_} for (split //, $str);

never seems to work...

Cheers