There's no need to carry $line_count, you can use $. instead.

And s!\n!!g; can be replaced with chomp.

Apart from that, your solution looks fine.

Assumes lines are always paired after the header line:

use strict;
use warnings;

print scalar <STDIN>;
while (<STDIN>) {
    chomp;
    print $_, scalar <STDIN>;
}
[download]

I like both CountZero's and BrowserUK's solutions. They are short and readable. However, since the version I was going to post is similar to BrowserUK's, I have to say I'm a little baised toward his solution. ;) The less code I need to read through to decipher functionality, the better.

---
s;;:<).>|{>?\\^0<|)=|*?=>|!./>(%<|:%<,|(!#+%<{;;y; -/:-@[-`{-};`-{/" -;;s;;$_;see;
Warning: Any code posted by tuxz0r is untested, unless otherwise stated, and is used at your own risk.

use strict;
<DATA>; # Throw away the header
while (<DATA>) {
    chomp if not $.%2;
    print;
}

__DATA__
Line 1: Header
Line 2: Keep me!
Line 3: Join me to the previous line.
Line 4: Keep me!
Line 5: Join me to the previous line.
Line 6: Keep me!
Line 7: Join me to the previous line.
Line 8: Keep me!
Line 9: Join me to the previous line.
[download]

Line 2: Keep me!Line 3: Join me to the previous line.
Line 4: Keep me!Line 5: Join me to the previous line.
Line 6: Keep me!Line 7: Join me to the previous line.
Line 8: Keep me!Line 9: Join me to the previous line.
[download]

Perhaps I had a little extra caffeine today, but I find this solution heartwarming.

There are a few interesting edge cases you may care to take care of. Consider:

use strict;
use warnings;

<DATA>;
print ''.(chomp, s/\s*$/ /, $_).($_ = <DATA>, s/^\s*(?=\S)//, $_) whil
+e <DATA>;

__DATA__
Header line
First line part 1.
Part 2 of first line.
Second line parts one  
  and two.
Third line - second part empty.

Fourth
and last line
[download]

Prints:

First line part 1. Part 2 of first line.
Second line parts one and two.
Third line - second part empty. 
Fourth and last line
[download]

which handles a number of cases, but spits warnings if the last line of the final pair is missing.

Aren't you missing a chomp? Assuming so, sSomething like:

my $fh = open_file( 'filename' );
print read_first_line( $fh );
print read_two_lines( $fh ) until eof( $fh );

sub read_first_line
{
    my $fh = shift;
    return scalar <$fh>;
}

sub read_two_lines
{
    my $fh = shift;
    chomp(my $first = <$fh>);
    return $first . <$fh>;
}
[download]

Aren't you missing a chomp?

I had this:

 s!\n!!g;
[download]

I have beheld the tarball of 22.1 on ftp.gnu.org with my own eyes. How can you say that there is no God in the Church of Emacs? -- David Kastrup

[tag://sort,etl,data] [download]

perl -pe"BEGIN{<>} chomp if $.%2==0"
[download]

Reads from STDIN or from the file provided as an argument.

>type data
Line 1: Header
Line 2: Keep me!
Line 3: Join me to the previous line.
Line 4: Keep me!
Line 5: Join me to the previous line.
Line 6: Keep me!
Line 7: Join me to the previous line.
Line 8: Keep me!
Line 9: Join me to the previous line.

>perl -pe"BEGIN{<>} chomp if $. % 2 == 0" data
Line 2: Keep me!Line 3: Join me to the previous line.
Line 4: Keep me!Line 5: Join me to the previous line.
Line 6: Keep me!Line 7: Join me to the previous line.
Line 8: Keep me!Line 9: Join me to the previous line.
[download]

# sample input:

$ ls | head -11
Desktop
Documents
Downloads
Library
Movies
Music
Pictures
Public
Sites
bin
cgi-bin

# 21-character perl script:

$ ls | head -11 | perl -pe 's{$/}{ } unless($.%2)'
Desktop
Documents Downloads
Library Movies
Music Pictures
Public Sites
bin cgi-bin
[download]

(update: That version replaces the default line termination with a space. If you just want to delete the line termination (first char of line 3 immediately follows last char of line 2, etc), take the space out of the replacement block in the regex, making it a 20-character script.)

Another update: oops! just noticed that I'm not supposed to output the first line, so I either have to lengthen the perl script, or else lengthen the command line:

# using a longer perl script:

$ ls | head -11 | perl -pe '$_="" if($.==1);s{$/}{ } unless($.%2)'
Documents Downloads
Library Movies
Music Pictures
Public Sites
bin cgi-bin

# using a longer command line:

$ ls | head -11 | tail +2 | perl -pe 's{$/}{ } if($.%2)'
Documents Downloads
Library Movies
Music Pictures
Public Sites
bin cgi-bin
[download]