Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question:

Hello All,

I'd like to be able to find the difference (in seconds) between two timestamps in this format:

MONTH DAY, YEAR HH:MM PM|AM

For example,

Mar 19, 2001 01:23 PM & Mar 19, 2001 03:52 PM

Of course, sometimes I could get:

Mar 19, 2001 11:42 AM & Mar 19, 2001 12:21 PM

or

Feb 29, 2001 11:23 PM & Mar 01, 2001 12:12 AM

Is there a module that does this? How could I correclty do this myself?

Replies are listed 'Best First'.
Re: TimeStamp Manipulation
by davorg (Chancellor) on Mar 20, 2001 at 15:10 UTC

    If the format of the dates that you are getting is pretty rigid (as it seems) then Date::Manip is probably overkill.

    Looks pretty simple to parse these dates into their component parts which you can then pass to timelocal to get the number of epoch seconds. Something like this:

    #!/usr/bin/perl -w

use strict;
use Time::Local;

my %mon = (Jan => 0, Feb => 1, Mar => 2, Apr => 3, May => 4,
           Jun => 5, Jul => 6, Aug => 7, Sep => 8, Oct => 9,
           Nov => 10, Dec => 11);

sub parse_date {
  local $_ = shift;

  my ($mon, $day, $year, $hr, $min, $am_pm) = split /\W+/;

  $mon = $mon{$mon};
  $year -= 1900;

  $hr += 12 if ($am_pm eq 'PM' and $hr != 12);

  timelocal(0, $min, $hr, $day, $mon, $year);
}

while (<DATA>) {
  chomp;
  my ($start, $end) = split(/ & /);

  print parse_date($end) - parse_date ($start), "\n";
}

__END__
Mar 19, 2001 01:23 PM & Mar 19, 2001 03:52 PM
Mar 19, 2001 11:42 AM & Mar 19, 2001 12:21 PM
Feb 29, 2001 11:23 PM & Mar 01, 2001 12:12 AM

    [download]

    Doesn't handle the last one correctly, but then Feb 29 2001 isn't a valid date! Might want to check for that too :)

    --
    <http://www.dave.org.uk>

    "Perl makes the fun jobs fun
    and the boring jobs bearable" - me

[reply]
[d/l]
      Just having fun with the spirit of TIMTOWTDI: 
      my @mon = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
my %mon = map { $mon[$_] => $_ } (0..$#mon);

      [download]
      Not as effiecient, but fun. :)

      Jeff 

      R-R-R--R-R-R--R-R-R--R-R-R--R-R-R--
L-L--L-L--L-L--L-L--L-L--L-L--L-L--
[reply]
[d/l]
Re: TimeStamp Manipulation
by dvergin (Monsignor) on Mar 20, 2001 at 14:05 UTC
    date::manip should do nicely. It's a bit large, but it can handle this sort of thing for you.
[reply]
Re: TimeStamp Manipulation
by Beatnik (Parson) on Mar 20, 2001 at 14:19 UTC
    Date::Calc is also pretty handy is this case

    Greetz
    Beatnik
    ... Quidquid perl dictum sit, altum viditur.
[reply]
      Thank you, but I forgot to mention that I am on a Win-32 platform using ActiveState. I do not have either Date::Calc or Date::Manip available.
[reply]
        Activestate has Date::Calc in their PPM listings, Date::Manip is listed too.

        Greetz
        Beatnik
        ... Quidquid perl dictum sit, altum viditur.
[reply]

Back to Seekers of Perl Wisdom