my @arr = (1 .. 1_000_000);
my $x   = 425983;
printf "search for $x? found at position: %s\n", binarySearch(0,$x,\@a
+rr);
[download]

One thing I noticed is that you pass in the array by reference (good idea), but the first thing you do is copy it entirely into a local variable. Why not keep accessing it by reference, like this: (I changed some other things around too)

sub binarySearch {
  my ($begin, $query, $array) = @_;

  return 0        if $query < $array->[0]        and $begin == 1;
  return $#$array if $query > $array->[$#$array] and $begin == 0;

  my ($left,$right,$prevCenter, $center) = (0, $#$array, -1);

  while(1) {
    $center = int (($left + $right)/2);

    if ($query == $array->[$center]) {
      if ($begin == 1)  {
        $center-- until $center == 0
                     or $array->[$center] != $array->[$center-1];
      } else {
        $center++ until $center == $#$array
                     or $array->[$center] != $array[$center+1];
      }
      return $center;
    }

    if ($center == $prevCenter) {
      return $right   if $begin == 1;
      return $right-1 if $begin == 0;
    }
    $right = $center if $query < $array->[$center];
    $left  = $center if $query > $array->[$center];
    $prevCenter = $center;
  }
}
[download]

Did you try one query (2seconds) or ~500 queries. For about ~500 queries, it takes about 5-7 minuetes. I think this is way too slow. Because, I need to make about 100,000 queries, which takes 1000 minutes (16 hours)....

"One thing I noticed is that you pass in the array by reference (good idea), but the first thing you do is copy it entirely into a local variable. Why not keep accessing it by reference, like this: (I changed some other things around too)"


Wow! I keep accessing it by reference, it runs in no time. Fantastic. Thanks a lot.

blokhead's analysis sounds true. When dealing with millions of values, Perl uses up all available memory.

Since you're only using integers, one method to reduce memory usage considerably is to use a string of packed integers. Tie::IntegerArray makes this transparent for you. (It's suppose to, at least. Untested.) Use it in conjunction with blokhead's change to use a reference.

my @integer_array;
tie @integer_array, 'Tie::IntegerArray',
    bits   => 32,
    signed => 1,
    size   => 1_000_000;  # Pre-allocate this many
[download]

By the way, why do you switch from a binary search to a linear search to find the beginning of a match?

"By the way, why do you switch from a binary search to a linear search to find the beginning of a match?" Since the array could contain duplicate entries, I just want to find the first (if begin = 1) or last (if begin=0) of the entries. Is there a better way to do it that to search linearly after I find my query?

Yes, stick with the binary search. Just change the terminating condition from

$query == $array->[$center]
[download]

to

$query == $array->[$center] && ($begin
   ? ($center == 0        || $query != $array->[$center-1])
   : ($center == $#$array || $query != $array->[$center+1])
)
[download]

You check the condition a second and third time later down, so you need to fix those too.

All together:

sub binarySearch {
  my ($begin, $query, $array) = @_;

  return 0        if $query < $array->[0]        and $begin == 1;
  return $#$array if $query > $array->[$#$array] and $begin == 0;

  my ($left, $right, $prevCenter) = (0, $#$array, -1);

  while(1) {
    my $center = int (($left + $right)/2);

    my $cmp =  $query <=> $array->[$center]
            || ($begin
                 ? ($center == 0        || $query != $array->[$center-
+1] ? 0 : -1)
                 : ($center == $#$array || $query != $array->[$center+
+1] ? 0 : +1)
               );

    return $center if $cmp == 0;
    if ($center == $prevCenter) {
      return $right   if $begin == 1;
      return $right-1 if $begin == 0;
    }
    $right = $center if $cmp < 0;
    $left  = $center if $cmp > 0;
    $prevCenter = $center;
  }
}
[download]

Update: Added code.

#!/usr/bin/perl
use strict;
use warnings;

my @array = 1 .. 3_141_592;

for (1 .. 400) {
    my $idx = bin_search(\@array, int(rand 3_141_592) + 1);
}


sub bin_search {
    my ($list, $tgt) = @_;

    return 0       if $tgt < $list->[0];
    return $#$list if $tgt > $list->[-1]; 

    my ($beg, $end, $val) = (0, $#$list, undef);
    while ($beg <= $end) {
        my $mid = int(($beg + $end) / 2);
        $val = $list->[$mid];
        if ($val > $tgt) {
            $end = $mid - 1;
        }
        elsif ($val < $tgt) {
            $beg = $mid + 1;
        }
        else {
            return $mid;
        }        
    }
    return -1;
}
[download]

It takes less than 1.5 seconds to run. Additionally, it takes almost exactly the same time if I don't run the bin_search(). In other words, the 400 searches take a negligible amount of time and the majority of the 1.5 seconds is building the array.

Now that I have looked at your code, I recognize it doesn't do everything you want. Modifying it shouldn't be difficult. Elsewhere in the thread you mention duplicates. If this array needs to be searched many times and will not change between searches, perhaps you should hash the index of the first position of each unique integer. Without knowing more about the problem - it is hard to offer optimization suggestions.

Awesome!!Completed in 55 seconds compared to my earlier code which took 6 hours!!