Re^4: Parsing XML w/ Attributes

I think it's safe to assume each host is there just once so it may be better to use ForceArray => ['process'] Which will somewhat simplify the code:

#!/usr/bin/perl -w
use strict;
use XML::Simple;

my $parser = new XML::Simple(ForceArray => ['process']);
my $ref = $parser->XMLin('c:\temp\file.xml');
foreach my $host (keys(%$ref)){
  foreach my $proc (keys(%{$ref->{$host}->{process}})){
    print "$proc is running on $host\n";
  }
}
[download]

Also it may be better to use each() instead of foreach():

#!/usr/bin/perl -w
use strict;
use XML::Simple;

my $parser = new XML::Simple(ForceArray => ['process']);
my $ref = $parser->XMLin('c:\temp\file.xml');
while (my ($host, $processes) = each %$ref){
  foreach my $proc (keys(%{$processes->{process}})){
    print "$proc is running on $host\n";
  }
}
[download]

Or using a different module:

use XML::Rules;
my $parser = XML::Rules->new(
    rules => {
        process => sub { '@list' => $_[1]->{name}},
        _default => sub { $_[0] => $_[1]->{list}},
        config => 'pass no content',
    }
);
my $data = $parser->parse(\*DATA);
#use Data::Dumper;
#print Dumper($data);

foreach my $host (sort keys %$data) {
    foreach my $proc (@{$data->{$host}}) {
        print "$host runs $proc\n";
    }
}

__DATA__
<?xml version="1.0" encoding="utf-8"?>
<config>
...
[download]

Jenda
Support Denmark!
Defend the free world!

Comment on Re^4: Parsing XML w/ Attributes Select or Download Code

Replies are listed 'Best First'.

Re^5: Parsing XML w/ Attributes
by jrsimmon (Hermit) on Dec 20, 2007 at 15:53 UTC

ForceArray => ['process']

[reply]
[d/l]

Re^6: Parsing XML w/ Attributes

by Jenda (Abbot) on Dec 20, 2007 at 18:04 UTC

It's the fact that you can name both the key and the value from the hash as you iterate so you do not have to use $hash{$key}, but instead have just $value. Which is especially handy if that hash is not in a variable, but rather is part of a more complex datstructure. So that instead of

foreach my $key (keys %{$data->{blah}[$idx]{blih}}) {
  print "$key : $data->{blah}[$idx]{blih}{$key}\n";
}
[download]

while (my ($key, $value) = each %{$data->{blah}[$idx]{blih}}) {
  print "$key : $value\n";
}
[download]

In that example it did not make a big difference especially because the value was used only once, but it may be handy. Especially if you find yourself doing something like

foreach my $key (keys %{$data->{blah}[$idx]{blih}}) {
  my $value = $data->{blah}[$idx]{blih}{$key};
  ...
}
[download]

Jenda
Support Denmark!
Defend the free world!

[reply]
[d/l]
[select]