But the value was initialized (I mean variable was declared).

$ perl -we 'my $x; print $x'
Use of uninitialized value in print at -e line 1.
[download]

I'm sure that if if you were to post some sample data somebody will offer better targetted help.

The part causing troubles is:

foreach my $id (@ids) {
       if ($id eq $NSC) {
           print MY $line;
       }
    }
[download]

and the uninitialized value is *** $id. ***.

You declare @ids about 20 ish lines above, and then populate the array with (reformatted, for clarity)

foreach my $row (@ids_table) {
    my @allcolumns = split /\t/, $row;
    if($count==0) {
        $myID= trim($allcolumns[0]);
    }
    else {
        $ids[$count] = trim($allcolumns[0]);
    }
    $count++;
}
[download]

You perform different actions on your input when $count is zero, but you're still adding it to the array with $ids[$count] = ... inside the else block. So, $ids[0] is always going to be undefined.

If you want to add something to the end of an array, use push, not subscripts.

That was really the problem. Perl didnt allow me to push into an empty array so I changed the code as follows: $ids[$count-1] = trim($allcolumns[0]) but I will push whenever possible :-). Thanks for help to Funky Monk and all the others.

Perl didnt allow me to push into an empty array...

Are you sure?

my @stuff;
push @stuff, 'element';
push @stuff, 'elephant';
local $" = ')(';
print "(@stuff)\n";
[download]

When $columns[$colN] is undefined, then trim returns undef which makes $NSC undefined causing the Uninitialized value in string eq error message.

To check this, right after spliting the columns just put in a check like:

...
while ($line = <ALL>) {
    my @columns = split /,/, $line;
    warn "column $colN not found" unless defined($columns[$colN]);
    ...
[download]

Thanks for the answer(s).
definitely the colum is there. It is a middle column and I am getting the error literally thousandtimes (every line I guess).

The part causing troubles is:


foreach my $id (@ids) {

       if ($id eq $NSC) {
           print MY $line;
       }
    }
[download]

and the uninitialized value is *** $id. ***. And it causes the error, I get the result but probably because thousands of error messages it takes longer time. Could the error be caused by the fact that i declared my @ids=()? I will check those libraries definitely, but it would take a begginer some time, so I am still seeking my error. Tx. to all karpatov

Well I incorported the recommended warn code (and will use the trick latter as well), but it is not executed, and the error is really on every single line :-(.

Welcome to the wonderful world of perl;) One of the best features of perl is CPAN http://www.cpan.org. Most common problems will have a solution ready made just waiting for you to find it.

Have a look at Text::CSV or Text::CSV_XS, the latter uses C for speed but you will need a compiler to install it. They provide all the functionality you need for parsing CSV files, are aware of all the traps and have been heavily tested.

#! perl --
use strict;
use warnings;


@ARGV == 3 or die "usage: $0 ID-file CSV-file CSV-output\n";

my $forextract = shift;    # IDs to be extracted, 1 per row , further 
+info tab delimited
                        #header[0] is matched against header of dtp_al
+l
my $dtp_all    = shift;    # csv CANCER60xxx.lis....
my $dtp_my     = shift;    # csv output

print "Warning: The file with items to extract has to have a header - 
+the first column name will be matched.\n";
open my $IDS, '<', $forextract or die "Opening $forextract failed: $!"
+;

my ( $myID, %ids );
while ( <$IDS> ) {
    /^\s*([^\t]+?)\s*\t/ or next;
    if ( $. == 1 ) {
        $myID = $1;
        }
    else {
        $ids{ $1 } = 1;
        }
    }

close $IDS;


open my $ALL, '<', $dtp_all or die "Opening $dtp_all failed: $!";
open my $MY,  '>', $dtp_my  or die "Opening $dtp_my failed: $!";

# copy the header
my $header = <$ALL>;
print $MY $header;
my @colnames = split /,/, $header, -1;

my $colN;
for my $col ( 0 .. $#colnames ) {
    if ( $colnames[ $col ] eq $myID ) {
        $colN = $col;
        last;
        }
    }
unless ( defined $colN ) {
    die "Column $myID not found.\n";
    }

# parse the input line by line, when ids matched write the line into t
+he output
while ( my $line = <$ALL> ) {
    my $col = ( split /,/, $line, -1 )[ $colN ];
    s/^\s+//, s/\s+$// for $col;
    if ( exists $ids{ $col } ) {
        print $MY $line;
        }
    }

close $MY or die "Not completed $dtp_my\n";
close $ALL;
[download]