chomp(my $library = <DATA>);
chomp(my $PIN = <DATA>);
while (my $line = <DATA>) {
    chomp($line);
    if ($line =~ /^library/) {
        $library = $line;
    } elsif ($line =~ /^PIN/) {
        $PIN = $line;
    } else {
        print "$library:$PIN:$line\n";
    }
}
[download]

#!/usr/bin/perl -l
use strict;
use warnings;

my $first_col = '';
while (<DATA>) {
    chomp;
    if (/^library/) {
        $first_col = $_;
    }
    else {
        print "$first_col:$_";
    }
}

__DATA__
library_AND
PIN.A
DELAY_TABLE 1 20 2 40 3 60 4 65 5 75;
DELAY_TABLE 1 10 2 15 3 45 4 70 5 80;
POWER_TABLE 20 30 40 50 80 97 110 20;
POWER_TABLE 3 4 5 6 10 80 90 10 20;
library_BUF
PIN.B
LEAKAGE 1 2 3 4;
TRANSIT 1.1 2 3.4;
[download]

Cheers,
Darren :)

Hi,
not quite, ++McDarren. The OP asked for some different output.


...
    if (/^library/) {
        $first_col = $_;
        my $secnd_col = <DATA>;
        chomp $secnd_col;
        $first_col .= ':' . $secnd_col;
    }
...
[download]


Regards,
svenXY

#!/usr/bin/perl 
use strict;
use warnings;

my @header;

map {
    unless (/;$/)
    {   
        chomp;
        scalar @header == 2 and undef @header;
        scalar @header and $_ = ":$_";
        push @header, $_; 
    }   

    print @header, ":$_" if /;$/;

} <DATA>;

__DATA__
library_AND
PIN.A
DELAY_TABLE 1 20 2 40 3 60 4 65 5 75;
DELAY_TABLE 1 10 2 15 3 45 4 70 5 80;
POWER_TABLE 20 30 40 50 80 97 110 20;
POWER_TABLE 3 4 5 6 10 80 90 10 20;
library_BUF
PIN.B
LEAKAGE 1 2 3 4;
TRANSIT 1.1 2 3.4;
[download]

library_AND:PIN.A:DELAY_TABLE 1 20 2 40 3 60 4 65 5 75;
library_AND:PIN.A:DELAY_TABLE 1 10 2 15 3 45 4 70 5 80;
library_AND:PIN.A:POWER_TABLE 20 30 40 50 80 97 110 20;
library_AND:PIN.A:POWER_TABLE 3 4 5 6 10 80 90 10 20;
library_BUF:PIN.B:LEAKAGE 1 2 3 4;
library_BUF:PIN.B:TRANSIT 1.1 2 3.4;
[download]

use strict;
use warnings;

open my $dataFH, q{<}, \ <<END_OF_FILE or die qq{open: $!\n};
library_AND
PIN.A
DELAY_TABLE 1 20 2 40 3 60 4 65 5 75;
DELAY_TABLE 1 10 2 15 3 45 4 70 5 80;
POWER_TABLE 20 30 40 50 80 97 110 20;
POWER_TABLE 3 4 5 6 10 80 90 10 20;
library_BUF
PIN.B
LEAKAGE 1 2 3 4;
TRANSIT 1.1 2 3.4;
END_OF_FILE

my $dataString = do
   {
       local $/;
       <$dataFH>;
   };

close $dataFH or die qq{close: $!\n};

my $rxGroup = qr
   {(?xs)
       (library_[^\n]+)\n
       ([^\n]+)\n
       (.*?\n)
       (?=(?:library_|\z))
   };

while ( $dataString =~ m{$rxGroup}g )
{
    print qq{$1:$2:$_\n} for split m{\n}, $3;
}
[download]

Here's the output.

library_AND:PIN.A:DELAY_TABLE 1 20 2 40 3 60 4 65 5 75;
library_AND:PIN.A:DELAY_TABLE 1 10 2 15 3 45 4 70 5 80;
library_AND:PIN.A:POWER_TABLE 20 30 40 50 80 97 110 20;
library_AND:PIN.A:POWER_TABLE 3 4 5 6 10 80 90 10 20;
library_BUF:PIN.B:LEAKAGE 1 2 3 4;
library_BUF:PIN.B:TRANSIT 1.1 2 3.4;
[download]

I hope this is useful.

Cheers,

JohnGG

Update: Removed superfluous my $group = from while clause, left over from earlier version. Original line was

while ( my $group = $dataString =~ m{$rxGroup}g )
[download]