foreach $month (%keys %ManagerInCharge) {
   my $month_hash = $ManagerInCharge{$month};
   my @month_array = @$month_hash{
      sort { $a <=> $b } keys %$month_hash
   };
   my $i;
   $ManagerInCharge{$month} = { map { ++$i => $_ } @month_array };
}
[download]

Or if you want to switch to a HoA,

foreach $month (%keys %ManagerInCharge) {
   my $month_hash = $ManagerInCharge{$month};
   my @month_array = @$month_hash{
      sort { $a <=> $b } keys %$month_hash
   };
   $ManagerInCharge{$month} = \@month_array;
}
[download]

If your keys are numbers, have you considered using an array instead?

I think what Corion is implying is that since you're squashing the second level keys to sequential indexen you could just keep them in an arrayref instead of a hash, and the element index would be the ID naturally (which makes sense; you'd just build a new parallel copy by walking over each sub-hash's values sorted by the key and push them into the new array).

The cake is a lie.
The cake is a lie.
The cake is a lie.

$ perl -e'
use Data::Dumper;

my %ManagerInCharge = (
    200610 => {
        56 => "jane",
        59 => "john",
        69 => "joe",
        100 => "frank",
        },
    200701 => {
        23 => "abel",
        11 => "gunder",
        37 => "frank",
        },
    );

print Dumper \%ManagerInCharge;

for my $hash ( values %ManagerInCharge ) {
    my $index = 1;
    for my $key ( sort { $a <=> $b } keys %$hash ) {
        $hash->{ $index++ } = delete $hash->{ $key };
        }
    }

print Dumper \%ManagerInCharge;
'
$VAR1 = {
          '200610' => {
                        '69' => 'joe',
                        '59' => 'john',
                        '56' => 'jane',
                        '100' => 'frank'
                      },
          '200701' => {
                        '11' => 'gunder',
                        '37' => 'frank',
                        '23' => 'abel'
                      }
        };
$VAR1 = {
          '200610' => {
                        '4' => 'frank',
                        '1' => 'jane',
                        '3' => 'joe',
                        '2' => 'john'
                      },
          '200701' => {
                        '1' => 'gunder',
                        '3' => 'frank',
                        '2' => 'abel'
                      }
        };
[download]

Update:

for my $hash ( values %ManagerInCharge ) {
    my $upper = keys %$hash;
    @{ $hash }{ 1 .. $upper } = delete @{ $hash }{ sort { $a <=> $b } 
+keys %$hash };
    }
[download]

But if you don't want to use an array, then this snippet could do:

for $hash (values %ManagerInCharge) {
    $i = 0;
    %$hash = (map {;++$i => $_} map $hash->{$_}, sort {$a <=> $b} keys
+ %$hash);
}
[download]

As for a technical answer: just order your keys and use a hash slice to pull out the values, and stuff them in an array.

my $hash = {
56 => "jane",
59 => "john",
69 => "joe",
100 => "frank",
};
my @array = @{$hash}{sort { $a <=> $b } keys %$hash};
[download]