You hadn't mentioned commas in the original post. Anyway to show that the approach works a complete program

#!/usr/bin/perl 
use 5.010_000;
use warnings;
use strict;

my %number_of;
my @words;

while ( my $line = <DATA> ) {
    $number_of{lines}++;
    $number_of{chars} += length $line;
    push @words, map { lc } split /[\s.,]+/, $line;
}
$number_of{words} = scalar @words;

foreach my $item (qw(chars words lines)) {
    say "Number of $item: $number_of{$item}";
}
say @words;

__DATA__
Hey, diddle, diddle,
The cat and the fiddle,
The cow jumped over the moon.
[download]

and the output

Number of chars: 75
Number of words: 14
Number of lines: 3
heydiddlediddlethecatandthefiddlethecowjumpedoverthemoon
[download]

If other punctuation is to be removed then you add it to the split. The difficulty would be with an apostrophe, you probably do not want to count don't as two words so the split line becomes

push @words, map { lc } # change to lower case
    map { tr/'//d; $_ } # remove apostrophes
    split /[\s.,?!"]+/, # split on space and punctuation
    $line;
[download]

Update: removed a useless use List::Util; from the example.