Here's the new method from Class::Accessor:

sub new {
    my($proto, $fields) = @_;
    my($class) = ref $proto || $proto;

    $fields = {} unless defined $fields;

    # make a copy of $fields.
    bless {%$fields}, $class;
}
[download]

If you haven't defined a new method of your own, that's what you're using. In that case, you can just write your own, based on that, to be something like this:

my $singleton;

sub new {
    my($proto, $fields) = @_;
    my($class) = ref $proto || $proto;

    if ( ! defined $singleton ) {
        $fields = {} unless defined $fields;

        # make a copy of $fields.
        $singleton = bless {%$fields}, $class;
    }

    return $singleton;
}
[download]

After that, you should be able to use it as usual with the caveat that after the first time the object is created, subsequent attempts to create it will not have the arguments to new honored. That is, if you do this:

my $c1 = C->new( foo => 'bar' );
my $c2 = C->new( foo => 12345 );
[download]

...then $c2->{foo} will still be 'bar'. If you're not passing any arguments to new, this won't be a problem.

If you've written your own new instead of using the one from Class::Accessor, you can adapt it in a similar way.