That's a cross product, not listing permutations or combinations.

It's trivial with Algorithm::Loops's NestedLoops.

use Algorithm::Loops qw( NestedLoops );

my @array1 = qw( A B );
my @array2 = qw( 1 2 );
my @array3 = qw( C D E );

my $iter = NestedLoops([
   \@array1,
   \@array2,
   \@array3,
]);
while (my @row = $iter->()) {
   print("@row\n");
}
[download]

Or perhaps some of the other combinatorics modules.

One module has already been suggested. I would suggest Algorithm::Loops and tell you that solving the problem yourself is quite fun.

#!/usr/bin/perl
use warnings;
use strict;

# read data into an array of arrays.

my @AoA = ();
while(<DATA>) {
    chomp;
    my @data = split /\,/, $_;
    push @AoA, [ @data ];
}

# determine the depth of the array.

my $depth = scalar @AoA;
print "Depth = $depth\n";

# use a recursive solution to handle arbitrary depth of the data.

permute ( \@AoA, "", 0 );

sub permute {
    my $aref = shift;
    my $string = shift;
    my $index = shift;
    if ( $index >= $depth ) {
        print $string, "\n";
        return;
    }
    for  (@{$aref->[$index]} ) {
        my $newstring = $string . $_;
        permute( $aref, $newstring, $index + 1) 
    }
}
__DATA__
A,B
1,2
C,D,E
[download]

C:\Code>perl permute_all.pl
Depth = 3
A1C
A1D
A1E
A2C
A2D
A2E
B1C
B1D
B1E
B2C
B2D
B2E

C:\Code>
[download]