You should take a look at the version module. It gives you standard comparison operators so you can just do this:

use version;

my $max = qv( "3.0.0.0" );
my $min = qv( "2.0.0.0" );
my @versions = (
    qv("1.0.0.0"),
    qv("1.1.10.1"),
    qv("2.0.0.0"),
    qv("2.1.0.0"),
    qv("10.6.1.0"),
);
my @constrained_versions = grep { 
   $max >= $_ and $min <= $_ 
} @versions;

print "@constrained_versions\n";
[download]

That should be ge and le rather than >= and <=.

Update: Both should work.

Assuming the individual numbers are in the range 0 - 255 then you can do this

my $min = canonical('2.0.0.0');
my $max = canonical('3.0.0.0');

my @versions = qw(1.0.0.0 1.1.10.1 3.1 2.0.1 1.9.9.9.9 3.0.0.0.0.0.0.1
+ 2.9 2.0.0.0 2.1.0.0 10.6.1.0);


foreach my $version (  @versions) {
    my $canonical = canonical($version);
    print "$version\n" if ( $min le $canonical && $canonical le $max )
+;
}

sub canonical {
    return pack 'C*', split /\./, $_[0];
}
__END__
2.0.1
2.9
2.0.0.0
2.1.0.0
[download]

Update: removed assumption that the version strings need to have the same number of numbers.

There is a CPAN module for everything...

use Sort::Versions;

my $min = '2.0.0.0';
my $max = '3.0.0.0';
my @list = qw( 1.0.0.0 1.1.10.1 2.0.0.0 2.1.0.0 10.6.1.0 );

for my $entry ( @list ) {
    next if versioncmp( $entry, $min ) < 0
         or versioncmp( $entry, $max ) > 0;

    print "$entry is between $min and $max\n";
}
[download]