There are two regex modifiers that help. /s so that . matches \n and /m so that ^ and $ match at the start and end of logical lines. /x allows free formating and embedded comments.

Using these modifiers you regex can be written as

my @array = $line =~ m{
    ^(LENGTH:     # a line beginning with LENGTH:
    .*?)          # as little as possible until
    ^(SUBJECT:    # a line beginning with SUBJECT:
    .*?)          # as little as possible until
    ^(COMMENT:    # a line beggining with COMMENT
    .*)           # and the rest 
}msx
[download]

$VAR1 = [
          'LENGTH: ...................................................
+...
..................................................................
..................................................................

...................................................................
..................................................................

',
          'SUBJECT: ..................................................
+.....

',
          'COMMENT: ..................................................
+...
....................................................................
'
        ];
[download]

If you want lines into strings:

my ( $key, %data );
while ( <FH> ) {
    if ( /^([^:]+):/ ) {
        $data{ $key = $1 } = $_;
        }
    else {
        $data{ $key } .= $_;
        }
    }
[download]

If you want lines into arrays:

my ( $key, %data );
while ( <FH> ) {
    if ( /^([^:]+):/ ) {
        $data{ $key = $1 } = [ $_ ];
        }
    else {
        push @{ $data{ $key } }, $_;
        }
    }
[download]

If you just want an array instead of a hash:

my ( $key, @data );
while ( <FH> ) {
    if ( /^([^:]+):/ ) {
        push @data, [ $_ ];
        }
    else {
        push @{ $data[ -1 ] }, $_;
        }
    }
[download]

Update: and with a single array:

my ( $key, @data );
while ( <FH> ) {
    if ( /^([^:]+):/ ) {
        push @data, $_;
        }
    else {
        $data[ -1 ] .= $_;
        }
    }
[download]

Hi,
jwkrahn++, but only if there are no further colons in the text...
Regards,
svenXY

Assuming that input starts with some uppercase key and that your keys are uppercase strings I would suggest following:

my $key;
while(<>)
{
    if(s/^([A-Z]+)://)
        { $key = $1 }
    push @{$hash{$key}}, $_
}

# use array consisting 'LENGTH'

print @{$hash{'LENGTH'}}
[download]

use strict;
use warnings;
use File::Slurp;

my $wholefile = read_file('data.txt');
my $capture = qr{(LENGTH|SUBJECT|COMMENT|\Z)};

while ($wholefile =~ m{^$capture:(.*?)(?=$capture)}smgcx) {
    my ($type , $data) = ($1 , $2);
    print "Type: $type\n";
    print "Data: $data\n";
}

Yet another approach to consider is one that might be used say with Perl's little brother, awk. This tool is based on the idea of “here's a bunch of regular-expressions and code-blocks. For each line, find the matching expression(s) and do what they say.” Importantly, there is also a BEGIN block that's executed before the first line, and an END block that's executed afterwards. (Yes, this is where Larry Wall got that idea...)

So what you can do is to define a “state machine” of sorts. For instance, when you see a line that starts with 'LENGTH' you go into this mode; when you see 'SUBJECT' you go into that mode, and so-on. The “mode” value then tells you what to do with each line that does not match any of these; say, a line consisting of dots.

What's “the right way” to do it? Of course there is none. But this approach is useful to put into your thinking-cap when you must deal with a more complicated issue such as parsing a printed-output file.

Finally, for very complicated inputs, you can actually use a true parser.

open(IN, "filename.txt");
$/ = '/delimiter here/';

while(<>) {

}
[download]