Using this as a base, it's fairly trivial to generate random words. You can restrict the length with the built in length function.

Alternatively, there is always CPAN - Data::Random::WordList, for example. You could use that to generate the words, and again use length to throw away the ones that are not the right length.

Update: And for no other reason than I felt like it ;), here is a short snippet of code that demonstrates how one might do this (in this case, using shuffle() from List::Util):

#!/usr/bin/perl -l
use strict;
use warnings;
use List::Util qw/shuffle/;

my $wordlist = '/usr/share/dict/words';

my $length = 10;
my $numwords = 10;

my @words;

open WORDS, '<', $wordlist or die "Cannot open $wordlist:$!";

while (my $word = <WORDS>) {
    chomp($word);
    push @words, $word if (length($word) == $length);
}

close WORDS;

my @shuffled_words = shuffle(@words);

print for @shuffled_words[0 .. 9];
[download]

Hope this helps,
Darren :)

Thank you for your help. Much appreciated. I like the List::Util version, the Data:Random:wordlist isn't that good at returning words of a given length. I needed to get a large list to ensure a number of words of the length required.

As others have suggested, if you want a dictionary word, you need a dictionary. The solutions I've seen so far, however, have involved loading the whole dictionary into memory to select your word. I think you could do this without loading the whole dictionary, however. See How do I pick a random line from a file? for the basic algorithm, which could be adapted to apply only to words of a certain length.

Update: I just couldn't resist writing it myself.

use strict;
use warnings;

my $desired_length = 8;
my $selected_word;
my $candidate_count = 0;

open my $dict_fh, '<', '/usr/share/dict/words'
    or die "Can't read '/usr/share/dict/words': $!\n";
WORD:
while ( my $word = <$dict_fh> ) {
    chomp $word;
    next WORD if length $word != $desired_length;
    $selected_word = $word if rand ++$candidate_count < 1;
}

print "Selected '$selected_word' out of $candidate_count candidates.\n
+";
[download]

my @word_list;

sub rand_word {
        my $file = shift;
        if ( not defined $word_list[0] ){
                open  FIN, "<$file" or die("$file");
                @word_list = map { chomp; $_ } <FIN>;
                close FIN;
        }

        my $r = int(rand(@word_list));
        return $word_list[$r];
}
[download]

# make the wordbase into an array
open(FH, "wordbase.txt");
my @words = <FH>;
close FH;

# select the word randomly in the wordbase
my $random_index = int(rand($#words));
my $random_word = $words[$random_index];

print "$random_word\n";
[download]

Just because, not because you should.