The fix suggested (unlink glob("$prefix$runid.*") or ...) will only report an error if no files can be unlinked. If only some files cannot be unlinked, no error will be reported. You probably want

unlink $_ or print "Error removing file \"$_\": $!\n"
   for glob("$prefix$runid.*");
[download]

I also doubt $! is set properly, especially when processing multiple files.

Replace the || with "or" and read up about operator precedence in perlop.

The precedence for || is pretty high. Your unlink would give a list context for glob(), but || gives it a scalar context instead. What you wrote is parsed as:

unlink ( glob(...) || print "..." );
[download]

This might show what's going on a little more:

sub print_context {
    my $wa = wantarray;
    print $wa ? 'list' : defined $wa ? 'scalar' : 'void';
    print "\n";
    return $wa ? (1, 2) : 'x';
}

print "with || :\n";
print print_context() || print "error";
print "\n";

print "with or :\n";
print print_context() or print "error";
print "\n";
__END__
with || :
scalar
x
with or :
list
12
[download]

Anyway, the short answer is to use or instead of ||, or use parentheses around the argument to unlink. These should work:

unlink( glob(...) ) || print "...";

unlink glob(...) or print "...";
[download]

perl -MO=Deparse,-p temp.pl
($prefix = 'test');
($runid = 12);
use File::Glob ();
unlink((glob("$prefix$runid.*") || print("Error removing files $!\n"))
+);
temp.pl syntax OK
[download]