I see a glaring mistake here. In Tk threaded apps, you MUST create the threads BEFORE any Tk code is invoked, or you will get thread-safety problems. Since you are invoking the thread from a Button, you already are risking thread safety. Just see threads: spawn early to avoid the crush. or search here for "Tk threads" and see how all the examples create the threads right before any Tk is called. So what you will need to do, is start your SerialPort stuff in the thread first, possible sitting in a while loop, waiting for a signal to start. THEN have a Tk Button that sets a shared variable to signal the while loop to start execution. I have an example at Tk-with-worker-threads.

Also, remember, that you can share the serial port filehandle through a thread by it's fileno.

#!/usr/bin/perl
use warnings;
use strict;
use threads;
use threads::shared;
use Tk;

my %shash;
#share(%shash); #will work only for first level keys
my %hash;

 share ($shash{'go'});
 share ($shash{'fileno'});
 share ($shash{'pid'});
 share ($shash{'die'});
 
 $shash{'go'} = 0;
 $shash{'fileno'} = -1;
 $shash{'pid'} = -1;
 $shash{'die'} = 0;

 $hash{'thread'} = threads->new(\&work);


my $mw = MainWindow->new(-background => 'gray50');

my $text = $mw->Scrolled('Text')->pack();

my $repeater;
my $buf;
my $startb = $mw->Button( -text => 'Start',
                -command=>sub{
                     $shash{'go'} = 1;
             $mw->after(1000);
             my $fileno = $shash{'fileno'};
                     print "fileno_m $fileno\n";
        
          open (my $fh, "<&=$fileno") or warn "$!\n";

                   while(<$fh>){
           
          $text->insert('end',$_);    
              $text->see('end');                  
              $mw->update;
           }


#                     $repeater = $mw->repeat(10,
#                sub {
#                      my $bytes = sysread( $fh, $buf, 8192);
#                  $text->insert('end',$buf);    
#                          $text->see('end');         
        #          if( $shash{'go'} == 0 ){ $repeater->cancel }
        
        
#               }
#             );             
        
             }
                 )->pack();

my $stopb = $mw->Button( -text => 'Stop',
                -command=>sub{
        
                 exit;
              },
                 )->pack();


MainLoop;

##################################################################
sub work{
    $|++; 
    while(1){
       if($shash{'die'} == 1){ goto END }; 
      
       if ( $shash{'go'} == 1 ){

        my $pid = open(FH, "top -b |" ) or warn "$!\n";
        my $fileno = fileno(FH);
        print "fileno_t->$fileno\n";
        $shash{'fileno'} = $fileno;
       
    $shash{'go'} = 0; #turn off self before returning      
       }else
         { sleep 1 }
    }
END:
}
###################################
[download]

All four code segments in Marrying Tk, threads and SerialPort - a COM port monitor open from the [Download] (found directly below the code) for me. Could you be a bit more explicit about "the code link for node 416132 is broken."?

You may also be served well by using Super Search for "serial" and "thread." If that doesn't get what you need, you might also try Perl Monks User Search for author zentara who may well be the leading light on Perl/Tk who's regularly here.

I see three blocks of sample code that don't seem to be 100% complete. At the bottom of the page is "The full code can be downloaded from here". Clicking on the "here" link redirects the browser to a "Sorry, the page you requested was not found" page.

I see three blocks of sample code that don't seem to be 100% complete. At the bottom of the page is "The full code can be downloaded from here". Clicking on the "here" link redirects the browser to a "Sorry, the page you requested was not found" page.

$widget->fileevent($fh, 'readable' => sub { ...call-back code... });
[download]

Also, since you are accessing the serial port as /dev/ttyS0, you should just be able to open and read/write to it directly just like any other file object:

open(S, '+<', '/dev/ttyS0');
read(S, $buf, 1024, length($buf));
print S "etc.\n";
[download]

Finally, I haven't tried it, but judging from this example code, file event call-backs should work even in a Win32 environment.

Update: Have a look at this page for an example of the fileevent call-back (under 'Executing Nonblocking System Commands') The code reads from a pipe, but the principle is the same with a serial port.