is there a more simple way to have the intersection of two lists ?

steph_bow has asked for the wisdom of the Perl Monks concerning the following question:

Dear Monks,

Is there another way to have the intersection of two lists ? Thanks a lot

Here is my code

#usr/bin/perl
use strict;

my $name_1 = q{list_1.txt};
my $name_2 = q{list_2.txt};

open my $INFILE_1, q{<}, $name_1 or die "Can't open $name_1 : $!";
open my $INFILE_2, q{<}, $name_2 or die "Can't open $name_2 : $!";


my @list_1;
while (my $line_1 = <$INFILE_1>){
    $line_1 =~ s/\s+$//;
    push @list_1, $line_1;
}    

my @list_2;
while (my $line_2 = <$INFILE_2>){
    $line_2 =~ s/\s+$//;
    push @list_2, $line_2;
}    

my @intersection;
my %count;

my $element;
my @two_lists = (@list_1,@list_2); 

print STDOUT "@two_lists\n";

foreach $element(@two_lists){
    $count{$element}++;
}

my $key;
my @KEYS = keys %count; 
foreach $key(@KEYS){
    if ($count{$key} == 1){
        print STDOUT "$key;$count{$key}\n\n";
    }    
}        

close $INFILE_1;
close $INFILE_2;
[download]

Here is the first file

car
train
plane
[download]

Here is the second file

boat
car
train
[download]

Comment on is there a more simple way to have the intersection of two lists ? Select or Download Code

Replies are listed 'Best First'.
Re: is there a more simple way to have the intersection of two lists ? by poolpi (Hermit) on Mar 18, 2008 at 13:58 UTC
See List::Compare `$lc = List::Compare->new(\@Llist, \@Rlist); @intersection = $lc->get_intersection;` [download] hth PooLpi 'Ebry haffa hoe hab im tik a bush'. Jamaican proverb	[reply] [d/l]
Re: is there a more simple way to have the intersection of two lists ? by dragonchild (Archbishop) on Mar 18, 2008 at 13:58 UTC
Use CPAN instead. `use Set::Scalar; my @filenames = ( 'name1.txt', 'name2.txt' ); my @sets = map { read_file_to_set( $_ ) } @filenames; my $intersection = $sets[0]->intersection( $sets[1] ); print "$intersection\n"; sub read_file_to_set { my ($filename) = @_; open my $fh, '<', $filename or die "Cannot open '$filename' for reading: $!\n"; chomp( my @lines = <$fh> ); close $fh; return Set::Scalar->new( @lines ); }` [download] My criteria for good software: Does it work? Can someone else come in, make a change, and be reasonably certain no bugs were introduced?	[reply] [d/l]
Re: is there a more simple way to have the intersection of two lists ? by alexm (Chaplain) on Mar 18, 2008 at 14:05 UTC
See also How can I find the union/difference/intersection of two arrays? on the Q&A arrays section.	[reply]
Re: is there a more simple way to have the intersection of two lists ? by zby (Vicar) on Mar 18, 2008 at 13:57 UTC
I use Set::Scalar and it really fits the way I think (my mathematical background taught me treat set operations as the basic 'atomic' functions). There is also Set::Bag if your lists are really multi-sets (i.e. can contain the same element multiple times).	[reply]
Re: is there a more simple way to have the intersection of two lists ? by moritz (Cardinal) on Mar 18, 2008 at 13:59 UTC
You don't have to write all that lines into an array: `my %count; while (my $line_1 = <$INFILE_1>){ $line_1 =~ s/\s+$//; $count{$line_1}++; } while (my $line_2 = <$INFILE_2>){ $line_2 =~ s/\s+$//; print $line_2, "\n" if $count{$line_2}; } # untested` [download]	[reply] [d/l]
Re^2: is there a more simple way to have the intersection of two lists ? by ysth (Canon) on Mar 19, 2008 at 06:36 UTC
A slight modification should make it work with duplicate elements (untested): `print $line_2, "\n" if $count{$line_2}-- > 0;` [download] -- Online Fortune Cookie Search	[reply] [d/l]
Re: is there a more simple way to have the intersection of two lists ? by ikegami (Patriarch) on Mar 18, 2008 at 14:39 UTC
If neither list contains duplicate elements: `my %seen; my @intersection = grep ++$seen{$_}==2, @list1, @list2;` [download] Or if they could `my %seen; $seen{$_}=1 for @list1; my @intersection = grep ++$seen{$_}==2, @list2;` [download] Update: `$seen{}` ⇒ `$seen{$_}`	[reply] [d/l] [select]
Re^2: is there a more simple way to have the intersection of two lists ? by ysth (Canon) on Mar 19, 2008 at 06:40 UTC
`my %seen; $seen{$_}=1 for @list1; my @intersection = grep ++$seen{}==2, @list2;` [download] You are missing a $_ there. And it doesn't work. (Consider `@list1=(); @list2=qw(foo foo);`.) -- Online Fortune Cookie Search	[reply] [d/l] [select]
Re^3: is there a more simple way to have the intersection of two lists ? by ikegami (Patriarch) on Mar 19, 2008 at 06:48 UTC
Hum, right. I over-optimized. I should have stuck to the general solution (i.e. accepts more than two sets) I first wrote. `my %seen; $seen{$_}\|=1<<0 for @list1; $seen{$_}\|=1<<1 for @list2; my @intersection = grep $seen{$_}==(1<<2)-1, keys %seen;` [download] It loses any order, though.	[reply] [d/l]
Re: is there a more simple way to have the intersection of two lists ? by kyle (Abbot) on Mar 18, 2008 at 14:50 UTC
If you read the first list into a hash instead of an array, you can then use a hash slice with the second array to get the intersection. #usr/bin/perl use strict; my $name_1 = q{list_1.txt}; my $name_2 = q{list_2.txt}; open my $INFILE_1, q{<}, $name_1 or die "Can't open $name_1 : $!"; open my $INFILE_2, q{<}, $name_2 or die "Can't open $name_2 : $!"; my %list_1; # changed while (my $line_1 = <$INFILE_1>){ $line_1 =~ s/\s+$//; $list_1{$line_1} = $line_1; # changed } my @list_2; while (my $line_2 = <$INFILE_2>){ $line_2 =~ s/\s+$//; push @list_2, $line_2; } close $INFILE_1; close $INFILE_2; # changed from here down my @intersection = grep { defined } @list_1{@list_2}; foreach my $line ( @intersection ) { print "$line\n"; } [download] This also requires that list 2 not have duplicate elements.	[reply] [d/l]