You were heading in the right direction with your first for loop - but it got away from you (don't you just hate it when that happens?). Use strict and warnings _and_ don't comment them out. :-)

Read up on Perl data structures, what you needed was a hash of arrays. e.g. Data Types and Variables

Good luck!

#!/usr/bin/perl 

use warnings;
use strict; 

my @country = (
 "Australia", "south","Austria","America","India","Zimbabwe"
); 

# build a table - a hash of arrays (HoA)
my %table;
foreach my $country (@country) { 
  my $init = uc substr($country,0,1); 
  push @{$table{$init}}, $country;
} 

# output the table
for my $letter (sort keys %table){
  print qq{$letter = };
  for my $country (sort @{$table{$letter}}){
    print qq{$country };
  }
  print qq{\n};
}
[download]

A = America Australia Austria 
I = India 
S = south 
Z = Zimbabwe
[download]

I will give you a clue, though. Think hash.

Longer clue: Implement a hash where the value is the concatenation of all names starting with the same first letter, and where the key is the first letter .

my @c=("Australia", "south","Austria","America","India","Zimbabwe");
my %h;

push @{  $h{uc substr($_,0,1)}   },   $_ for @c;

for my $l(sort keys %h){
  print "$l\n=\n";  
  print "$_\n" for sort @{$h{$l}};
  print "\n"
}
[download]

my @country = ("Australia", "south","Austria","America","India","Zimba
+bwe");
my %list;
foreach (@country) {
    /^(.)/ and push @{$list{uc $1}}, $_;
}

foreach (sort keys %list) {
    print "$_\n=\n";
    print "$_\n" for sort @{$list{$_}};
    print "\n";
}
[download]