#!/usr/bin/perl -w
use strict;

my $ref=\&this;
my $x=$ref->();
print "$x\n";
sub this {return "hi!"}
[download]

yay FunkyMonk &thanks

In addition to "no strict 'refs'" (which would be my first suggestion), there are a few other ways with various advantages.

If you know all the subs you want to reference this way, you could use a dispatch table.

my %sub_named
    = ( this => \&this,
        that => \&that,
      );
my $ref = 'this';
my $x;
if ( exists $sub_named{ $ref } ) {
    $x = $sub_named{ $ref }->();
}
else {
    # error, no sub named $ref
}
[download]

You could even make the dispatch table dynamic using eval.

my @sub_list = qw( this that );
my %sub_named = map { $_ => eval "\\&$_" } @sub_list;
# etc.
[download]

This way, you can see what subs are available before trying to take a leap into one of them.

You can also use eval directly.

use English '-no_match_vars';

my $ref = 'this';
my $x = eval "&$ref()";
if ( my $error_message = $EVAL_ERROR ) {
    if ( $error_message =~ /^Undefined subroutine / ) {
        # a dispatch table would have caught this
    }
}
[download]

This is actually kind of clumsy. On the other hand, if you're not using a dispatch table, you might want to wrap calls in an eval anyway to catch that moment when you try to call a sub that doesn't exist.

I haven't run and tested the code here, but it should work.

my $name = "this";
my $code_ref = main->can($name);
$code_ref->(...);
[download]

my $sub_name = 'this';
my $x = do { no strict 'refs'; \&$sub_name };
print $x->(), "\n";
sub this {
    return "hi";
}
[download]

Note that I kept the scope small in which I used the no strict "refs"; to prevent damage from unwanted symbolic dereferentition.

use strict;

my $ref="this";
my $x;
{
  no strict 'refs';
  $x=&$ref();
}
print "$x\n";
sub this {return "hi!"}
[download]

But either of the following will in fact work (the second only under some conditions):

my $x=sub{goto &$ref}->();
[download]

my $x=&{$::{$ref}}();
[download]