my %sorted;
   foreach my $item (@array) {
     my ($prefix) = $item =~ /^(\w+)/;
     push @{$sorted{$prefix}}, $item;
   }
[download]

Then you can work your way through the list of items for each prefix like this:

   foreach my $prefix (keys %sorted) {
     my @items = @{$sorted{$prefix}};
     # do something with @items...
   }
[download]

Does that make sense?

-sam

my @array = qw(001.file.a 001.file.b 002.file.a 002.file.b) ;

my %groups;
for my $filename ( @array ) {
    my $prefix = (split /\./, $filename)[0];
    push @{ $groups{$prefix} }, $filename;
}

for ( keys %groups ) {
    print "group $_ has files @{ $groups{$_} }\n"
}
[download]

Output:

group 002 has files 002.file.a 002.file.b
group 001 has files 001.file.a 001.file.b
[download]

use strict;
use warnings;
my @files = qw(001.file.a 001.file.b 002.file.a 002.file.b);

my @sorted_files;

for (@files){
    if (m/^(\d+)\./){
        push @{$sorted_files[$1]}, $_;
    } else {
        die "File name with unknown format: '$_'\n";
    }
}

for my $bucket (0 .. $#sorted_files){
    print "Processing bucket $bucket\n";
    for (@{$sorted_files[$bucket]}){
        print "\tprocessing file $_\n";
    }
}
__END__
Processing bucket 0
Processing bucket 1
        processing file 001.file.a
        processing file 001.file.b
Processing bucket 2
        processing file 002.file.a
        processing file 002.file.b
[download]

Danger! If you ever encounter a file called "10000000000000000.file.a" your program will run out of memory and crash. Perl's arrays are not sparse so when you ask for $array[10000000000000000] you're going to allocate a great hunk of memory.

-sam

Seems like you need to "sub-select" your list. Given that it's not in order, I'd build a hash of arrays (HoA) with the keys corresponding to your selections, then process them in whatever order you wanted.

#!/usr/bin/perl -w
use strict;

my @array = qw(001.file.a 001.file.b 002.file.a 002.file.b);
my %hash;
for my $filename (@array){
    $filename =~ /^(\d+)/;
    push @{$hash{$1}}, $filename;
}

for my $group (sort { $a <=> $b } keys %hash){
    print "Processing group '$group':\n";
    for my $file (@{$hash{$group}}){
        print "\tProcessing $file:\n";

        ### Do stuff

    }
}
[download]

Update: Wow, you guys are quick. I hit the 'Comment' link, typed out the code, previewed it, and posted it - and suddenly there were three posts ahead of me where there had been zero. I guess I'd better learn to type faster. :) It's also amusing (but unsurprising) that all of us gave essentially the same answer, so I'm going to '++' everyone 'cause they're so brilliant. :)

-- 
Human history becomes more and more a race between education and catastrophe. -- HG Wells

Thanks everybody! This is exactly what I was trying to do. Much appreciated! a:)