Try it this way:

sub Button1_Click {
    open my $file, '<', "bigfile.txt" or die "$!";

    ## One line at a time
    while( <$file> ) {
        ## skip it if it doesn't contain the text
        next unless m[be]; 

        my @posns;
        ## Find the positions
        push @posns, [ $-[0], $+[ 0 ] ] while m[be]g;

        ## Get the current length
        my $oldLen = $RichText->TextLength;

        ## Move the seletion to the end and insert the line
        $RichText->SetSel( -1, -1 );
        $RichText->ReplaceSel( $_ );

        ## for each position found
        for( @posns ) {
            ## Set the selection to it,
            ## adjusting for the length of the previous contents
            $RichText->SetSel( map $oldLen + $_, @$_ );

            ## And highlight it
            $RichText->SetCharFormat( -color => "#ff0000" );
        }
    }
    close $file;
}
[download]

Ask if anything need clarifying.

Few comments. You need to use \b boundary condition to avoid higlighting say the "be" in because.

The problem per se is that ReplaceSel is very slow and you hit it a lot.

You can do the RTF formatting task very simply if you understand the format. Here is a sub that will highlight all the matches in a given text string and output RTF format data. It will only process TXT data, not existing RTF.

# RGB format a text document using a highlight colour. 
# RGB 0-255 like HTML 0x00-0xFF
# Output should be valid RTF but YMMV

sub RTFhighlight {
    my ($text, $highlight, $r, $g, $b, $font) = @_;
    $font ||= "Arial";
    $text =~ s/([\\{}])/\\$1/g;  # escape \ and { }
    $text =~ s/\n/\\par\n/g;     # convert \n to \par
    $text =~ s/\b\Q$highlight\E\b/\\cf1 $highlight\\cf0 /g;
    my $header = "{\\rtf1\\ansi\\ansicpg1252\\deff0\\deflang1033{\\fon
+ttbl{\\f0\\fswiss\\fcharset0 $font;}}\n";
    $header   .= "{\\colortbl ;\\red$r\\green$g\\blue$b;}\n";
  return $header.$text;
}

print RTFhighlight("hello be seabe be because", "be", 0, 0, 0xFF);
[download]

To use it in your code just read in all the text in a single pass, highlight it, and set it. This is still a bit slow because of the ReplaceSel issue. You can get it to display chunks of the file by iterating over chunks of your file but the price is lots more calls to ReplaceSel so although you get the satisfaction of some output straight away it takes a lot longer to finish. This takes about 6 seconds to do 20,000 highlights in a 250k file on my el cheapo laptop. Creating the highlight text takes a few milliseconds, all the rest of the time we are waiting for ReplaceSel.

One final note. You should delay showing the window until you have finished adding widgets. That way it will render properly when it appears ie move Win->Show.