-foo not readonly in fun(-foo => 1) in perl v5.8.7

Jenda has asked for the wisdom of the Perl Monks concerning the following question:

I wanted to use Scalar::Util::readonly() to help distinguish between foo( 1,2,3) and foo( -one => 1, -two => 2, -three => 3), but it looks like there is an error (or at least an unexpected behaviour) in Perl. At least in my version. If I call foo( named => 1) then $_[0] is readonly, if I call foo( -named => 1), it's not.

use strict;
use Carp;
use Scalar::Util qw(readonly);

sub ro {
    print "readonly($_[0])=".readonly($_[0])."\n";
    $_[0] = 'xxx';
}
eval { ro('lonely') } or print $@;
eval { ro(named => 4); } or print $@;
eval { ro(-named => 7); } or print $@;

for (1..5) { # to test whether changing $_[0] affects the literal
  eval { ro(-loop => 7); } or print $@;
}
[download]

I guess the

V:\>perl -MO=Deparse -e "%a = (-foo => 1);"
(%a) = (-'foo', 1);
-e syntax OK
[download]

explains it ... I expected the -foo => 1 to be parsed as (or optimized to) '-foo' => 1, but it looks like its not. What do you get with your version of perl?

Update: There seems to be a speed difference as well:

use strict;
use Benchmark;

sub woH {
    my %a = (
        -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1,
+ -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a =>
+ 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a
+ => 1,
        -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1,
+ -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a =>
+ 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a
+ => 1,
        -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1,
+ -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a =>
+ 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a
+ => 1,
        -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1,
+ -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a =>
+ 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a
+ => 1,
        -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1,
+ -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a =>
+ 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a => 1, -a
+ => 1,
    );
    return;
}

sub wH {
    my %a = (
        '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' =>
+ 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1,
+ '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-
+a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1,
        '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' =>
+ 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1,
+ '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-
+a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1,
        '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' =>
+ 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1,
+ '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-
+a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1,
        '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' =>
+ 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1,
+ '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-
+a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1,
        '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' =>
+ 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1,
+ '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-
+a' => 1, '-a' => 1, '-a' => 1, '-a' => 1, '-a' => 1,
    );
    return;
}

timethese 100000, {
    woH => \&woH,
    wH => \&wH,
}
__END__
Benchmark: timing 100000 iterations of wH, woH...
        wH:  1 wallclock secs ( 1.45 usr +  0.00 sys =  1.45 CPU) @ 68
+917.99/s (n=100000)
       woH:  3 wallclock secs ( 2.39 usr +  0.00 sys =  2.39 CPU) @ 41
+893.59/s (n=100000)

Benchmark: timing 100000 iterations of wH, woH...
        wH:  2 wallclock secs ( 1.47 usr +  0.01 sys =  1.48 CPU) @ 67
+521.94/s (n=100000)
       woH:  2 wallclock secs ( 2.32 usr +  0.02 sys =  2.34 CPU) @ 42
+735.04/s (n=100000)

Benchmark: timing 100000 iterations of wH, woH...
        wH:  1 wallclock secs ( 1.42 usr +  0.00 sys =  1.42 CPU) @ 70
+472.16/s (n=100000)
       woH:  3 wallclock secs ( 2.56 usr +  0.00 sys =  2.56 CPU) @ 39
+077.76/s (n=100000)
[download]

Another strange thing:

D:\>perl -MO=Deparse -e "print -'ahoj' => 1"
print '-ahoj', 1;
-e syntax OK

D:\>perl -MO=Deparse -e "print -ahoj => 1"
print -'ahoj', 1;
-e syntax OK
[download]

Jenda
Support Denmark!
Defend the free world!

Comment on -foo not readonly in fun(-foo => 1) in perl v5.8.7 Select or Download Code

Replies are listed 'Best First'.

Re: -foo not readonly in fun(-foo => 1} in perl v5.8.7
by elmex (Friar) on Apr 19, 2008 at 17:02 UTC

I've got perl 5.10, and get this:

# perl script12
readonly(lonely)=134217728
Modification of a read-only value attempted at f2 line 7.
readonly(named)=134217728
Modification of a read-only value attempted at f2 line 7.
readonly(-named)=0
readonly(-loop)=0
readonly(-loop)=0
readonly(-loop)=0
readonly(-loop)=0
readonly(-loop)=0
[download]

[reply]
[d/l]

Re^2: -foo not readonly in fun(-foo => 1} in perl v5.8.7

by apl (Monsignor) on Apr 20, 2008 at 13:29 UTC

Or to put it another way, the OP was trying to set the string 'lonely' to the value of 'xxx'.

[reply]

Re: -foo not readonly in fun(-foo => 1} in perl v5.8.7 (wishes)
by tye (Sage) on Apr 20, 2008 at 03:57 UTC

I wanted to use Scalar::Util::readonly() to help distinguish between foo( 1,2,3) and foo( -one => 1, -two => 2, -three => 3),

That brings to mind "and I wanted a pony".

If you had come to me with that idea, I would have told you that you need to solve your problem in a different way. Even if you hadn't already found out that your trick is broken for some environments, I would have warned you that your idea is inherently fragile. It will be broken by a matter of optimization within Perl. There is no guarantee of the behavior that you assumed.

It is also extremely fragile in the face of simple changes to how your code is used. You should feel guilty considering making code that breaks between these two usages:

    foo( -bar => 1 );

    my %args= ( -bar => 1 );
    foo( %args );
[download]

I think the better alternative is nearly obvious so I won't spend time describing it at this time.

- tye

[reply]
[d/l]
[select]

Re^2: -foo not readonly in fun(-foo => 1} in perl v5.8.7 (wishes)

by Jenda (Abbot) on Apr 20, 2008 at 08:23 UTC

I don't want a pony. Don't have a place to put it. Prettymuch anything you do with named parameters in Perl, except for requiring their use and forbiding positional parameters completely, is fragile in one way or another.

If by the better alternative you mean

foo( 1, 2, 3);
foo({ one => 1, two => 2, three => 3}); #with or without dashes
[download]

Besides ... I would not feel guilty about that example ... that call doesn't look like a named-parameters call so it's not one. I can live with that. On the other hand if there was a way to distinguish between -foo and '-foo' that would work as well ... it's very unlikely that anyone would ever write $stringvar = -foo; or $stringvar = -$otherstring.

Apart from being unable to tell between one positional hashref and several named params in foo({ -one > 1, -two => 2}); there is one more reason I don't want to do that. With foo( inparam => 31, outparam => $var) I can modify the $var from within foo(), with foo({ inparam => 31, outparam => $var}) I could not. While mostly I do think that functions should take (readonly) parameters and return some value(s), if possible without side effects, in case the subroutine is a wrapper of a database's stored procedure without output parameters, I do need to allow that. And I do not really like foo({ inparam => 31, outparam => \$var}).

Jenda
Support Denmark!
Defend the free world!

[reply]
[d/l]
[select]