All right then... so I suppose I will write you up a short example of POST-ing to a web server, w/o using modules (except for Socket, but you *really* should have that one)--(and not that you really asked :).

WARNING: this may not be great code. But I think it's got the essentials of what you need to do to write a client that POSTs to a web server and receives a response.

use Socket;

# remote hostname and port (80, most likely)
my $remote = "www.server.com";
my $port = 80;

# the URL you want to POST to
my $url = "/cgi-bin/form.pl";

# the content you want to POST
# (key value pairs, most likely)
my $content = "id=103";

# network stuff--lookup host name and convert
# it into a packed IP address suitable for
# passing to connect. then get the protocol
# data needed by socket (for the "tcp" protocol).
my $paddr = sockaddr_in $port, inet_aton $remote;
my $proto = getprotobyname('tcp');

# open up a socket on your local machine
socket S, &AF_INET, &SOCK_STREAM, $proto
    or die "Can't open socket: $!";

# connect your local socket to the remote host and port
connect S, $paddr
    or die "Can't connect: $!";

# make your socket unbuffered
select((select(S), $|=1)[0]);

# print POST line to web server, followed by
# Content-Length header--this header is essential
# so that the web server knows that content will
# be sent along in the body of the request
print S "POST $url HTTP/1.0\n";
print S "Content-Length: ", length $content, "\n";
print S "\n";
print S $content, "\n\n";

# you've sent the request, now just read back the
# response, headers and all, and print it
print while <S>;

# close up the socket
close S;
[download]