How do I find matching/nesting anything?

This isn't something that can be done in one regular expression, no matter how complicated. To find something between two single characters, a pattern like /x([^x]*)x/ will get the intervening bits in $1. For multiple ones, then something more like /alpha(.*?)omega/ would be needed. But none of these deals with nested patterns. For balanced expressions using (, {, [ or < as delimiters, use the CPAN module Regexp::Common, or see "(??{ code })" in perlre. For other cases, you'll have to write a parser.

my %arg_xlate = ( func1 => sub { "proc1{$_[0]}" }
                , func2 => sub { "FUNC $_[0] END" } );
while (<DATA>) {
  my $line = $_;
  0 while ($line =~ s/(func[12])\(([^()]*)\)/$arg_xlate{$1}($2)/ge);
  print $line;
}

__DATA__
func1(input1, func2(input2, input3))
func2(func1(input1, input2), input3)
[download]

use strict;
use warnings;

use re q{eval};

my @codeStrings = (
   q{func2(func1(input1, input2), input3)},
   q{func1(input1, func2(input2, input3))},
   q{Contains i(mbalan(ced Br(ack)ets, )one op)en m)missing},
   q{So(me m(ultip)le n(est(s in) thi)s o)ne},
   );

my @memoList;
my $rxNest;
$rxNest = qr
{(?x)
   (
      \(
      [^()]*
      (?:
         (??{$rxNest})
         [^()]*
      )*
      \)
   )
   (?{ [ @{$^R}, $^N ] })
};

my $rxOnlyNested;
{
    $rxOnlyNested = qr
    {(?x)
       (?{ [] })
       ^
       [^()]*
       (?:
          $rxNest
          [^()]*
       )+
       \z
       (?{ @memoList = @{$^R} })
    };
}

testString($_) for @codeStrings;

sub testString
{
    my $string = shift;
    @memoList = ();
    print qq{\nString: $string\n};
    if($string =~ /$rxOnlyNested/)
    {
        print qq{     Match succeeded\n};
        print qq{     ---------------\n};
        print qq{     Before brackets:-\n};
        print qq{       -->@{[substr $string, 0, $-[1]]}<--\n};
        print qq{     Bracket pairs:-\n};
        print qq{          $_\n} for @memoList;
        print qq{     After brackets:-\n};
        print qq{       -->@{[substr $string, $+[1]]}<--\n};
    }
    else
    {
        print qq{     Match failed\n};
    }
}
[download]

The output.

String: func2(func1(input1, input2), input3)
     Match succeeded
     ---------------
     Before brackets:-
       -->func2<--
     Bracket pairs:-
          (input1, input2)
          (func1(input1, input2), input3)
     After brackets:-
       --><--

String: func1(input1, func2(input2, input3))
     Match succeeded
     ---------------
     Before brackets:-
       -->func1<--
     Bracket pairs:-
          (input2, input3)
          (input1, func2(input2, input3))
     After brackets:-
       --><--

String: Contains i(mbalan(ced Br(ack)ets, )one op)en m)missing
     Match failed

String: So(me m(ultip)le n(est(s in) thi)s o)ne
     Match succeeded
     ---------------
     Before brackets:-
       -->So<--
     Bracket pairs:-
          (ultip)
          (s in)
          (est(s in) thi)
          (me m(ultip)le n(est(s in) thi)s o)
     After brackets:-
       -->ne<--
[download]

I hope this helps you.

Cheers,

JohnGG

Update: I've found the post this originally came from, diotalevi, ikegami and hv gave me lots of help in finding this solution.

#!perl -l

use strict;

my @a=("func2(func1(input1, input2), input3)", "func1(input1, func2(in
+put2, input3))");
my $re = "";
$re=qr{\((((?>[^()]+)|(??{ $re }))*)\)};

for my $line (@a) {
    $line =~ s/func1$re/proc1{$1}/g;
    $line =~ s/func2$re/FUNC $1 END/g;
    $line =~ tr/{}/()/;
    print $line;
}
[download]

I wanted to say thanks for the input and suggestions. I was hoping for the continued use of a 1-line regex as, to be honest, this is a proof of concept that I will have to translate to C# and .NET.

I am still digesting the replies and will see what can be done.