split /\.*/ is wrong. (So is split /.*/ which is probably what you intended.) You don't have a list of items seperated by 0 more or more periods. You want split //.

split /\.*/ results in you only checking the first character of every line and the ones after periods, and it results in you doing ord('') (which returns zero) when the line starts with a period.

There are other issues, though.

• You chomp $line, but you split $_. Why do you have $line at all?
• You really should use use strict; and use warnings;. As it is, you'll find some variables you forgot to scope using my.
• while (@character){my $character = shift @character;
  can be written as
  for my $character (@character)
• @character is singular even though it holds many characters.
• There's no reason to use BEGIN where you did.
• The -s is check is redundant with open.
• warn and exit 255 can be replaced with die unless you specifically want code 255.
• It helps to include the reason ($!) the open failed.
• Your complex if can be collapsed.

use strict;
use warnings;

@ARGV == 1
  or die("Usage: $0 FILE\n");

my $in = shift;
open(INFILE, '<', $in)
   or die("Can't open $in for reading: $!\n");

while (<INFILE>) {
  chomp;
  for my $char (split //) {
    my $ord = ord($char);
    if (  $ord < 9
       || ($ord > 10 && $old < 32)
       || $ord > 126
    ) {
      print("$in contains illegal character \(ord:\ ", "$ord\) on line
+ $.\n");
    }
  }
}
[download]

It's usually better to use <> instead of opening the file yourself. This allows input to be read from STDIN if no filename is provided.

use strict;
use warnings;

while (<>) {
  chomp;
  for my $char (split //) {
    my $ord = ord($char);
    if (  $ord < 9
       || ($ord > 10 && $old < 32)
       || $ord > 126
    ) {
      print("$Input contains illegal character \(ord:\ ", "$ord\) on l
+ine $.\n");
    }
  }
}
[download]

Furthermore, you could use a regexp instead of splitting.

use strict;
use warnings;

while (<>) {
  chomp;
  while (/[^\x09\x20-\x7E]/g) {
    print("Input contains illegal character \(ord:\ ", "$ord\) on line
+ $.\n");
  }
}
[download]

split /\.*/ results in you only checking the first character of every line and the ones after periods

What you describe would happen with /\.+/  — as long as there are no periods, /\.*/ does split up individual characters just like //.   (Not saying that it should be used here, though...)

> as long as there are no periods, /\.*/ does split up individual characters just like //. No, it doesn't.

@c = split /\.+/, "abcdefg";
@d = split /\.+/, "ab.c.....defg";
[download]

results in @c having one element, "abcdefg", and @d having 3 elemnts, "ab", "c", and "defg".

Unless you really want to print every time you find a rougue char you can just use tr:

$str = join '', map{chr}0..255;
$str =~ tr/\11\12\40-\176//cd;       # ascify aka remove all crap char
+s
print $str, $/;
[download]

The /c is complement the list of desired characters, the /d deletes those that don't match. The good printable ASCII characters are specified in octol but you can use hex. To do what you are doing with a regex (here the chars are expressed as hex just to shown TIMTOWTDI):

while (<DATA>) {
    while ( m/([^\x09\x0A\x20-\x7E])/g ) {
        printf "Found chr %d on line %d at pos %d\n", ord($1), $., pos
+($_);
    }
}
[download]

if ($line =~ m/([\0-\x8\xb-\x1f\x7e-\xff])/) {
  print "$line contains illegal character (ord: ", ord($1), ")\n";
}
[download]

  @character=split /\.*/;
  while (@character){
[download]

  @character=split //; # split $_ into single characters
  while (@character){
[download]

Thanks to you all for those very useful replies.

You've taught me a lot.