You need to define what you mean by your default IP address. Essentially the hosts file on Win32 typically contains just an entry for localhost. If this is all you have, plus another IP then all you need to do is overwrite the old hosts file with new data, rather than mess around with finding one IP and replacing it.

my $hosts = "C:/windows/system32/drivers/etc/hosts";

print "Line to add to hosts (x.x.x.x domain.com): ";
my $line = <STDIN>;

rename( $hosts, "$hosts.old" );  # effectively make backup

open FILE, ">$hosts" or die "Can't write $hosts $!\n";
print FILE "127.0.0.1 localhost\n$line";
close FILE;
[download]

If you actually want to find a line and replace it the approach is a little different.

my $hosts = "C:/windows/system32/drivers/etc/hosts";

print "Line to add to hosts (x.x.x.x domain.com): ";
my $line = <STDIN>;
print "IP to replace: ";
chomp( my $ip = <STDIN> );

rename( $hosts, "$hosts.old" );

open IN, "$hosts.old" or die "Can't read $hosts.old $!\n";
open OUT, ">$hosts" or die "Can't write $hosts $!\n";
while (my $old = <IN>) {
    print OUT $old unless $old =~ m/\Q$ip/;  
}
print OUT $line;  # add the new record
close IN;
close OUT;
[download]

If you just want to change the IP then you need to get the old ip and new ip in like at the start (remember to chomp input to remove newline). Within the loop you would just do:

    $old =~ s/\Q$old_ip\s+/$new_ip /;
    print OUT $old;
[download]

and drop the print after the loop.

You can do it in a one liner. This particular syntax can come in very handy:

C:\>perl -pi.bak -e "s/this/that/g" <file>
[download]

This makes a backup called file.bak and replaces all instances of this with that in the original

...and finding the default IP address and replacing it with the new value.

Since the hosts file shouldn't change that much, here's a simple approach that might work for you:

1. Create a copy of the hosts file without the default ip address entry. Call this file hosts-base
2. When the default IP address needs to changed, copy hosts-base to hosts and append the new default address entry.

open(B, "<c:/path/to/hosts-base");
open(N, ">c:/path/to/hosts");
while (<B>) { print N; }
print N "default $ARGV[0]\n"; # add the 'default' entry
[download]

# Copyright (c) 1993-1999 Microsoft Corp.
#
# This is a sample HOSTS file used by Microsoft TCP/IP for Windows.
#
# This file contains the mappings of IP addresses to host names. Each
# entry should be kept on an individual line. The IP address should
# be placed in the first column followed by the corresponding host nam
+e.
# The IP address and the host name should be separated by at least one
# space.
#
# Additionally, comments (such as these) may be inserted on individual
# lines or following the machine name denoted by a '#' symbol.
#
# For example:
#
#      102.54.94.97     rhino.acme.com          # source server
#       38.25.63.10     x.acme.com              # x client host

127.0.0.1       localhost
192.168.1.108    chrome
192.168.1.105    legba
[download]

Suppose the aptly named legba machine is the default and you need to change its IP address.

# set_default_host.pl
use strict;
use Regexp::Common qw /net/;

if (scalar @ARGV == 1 and $ARGV[0]=~/^$RE{net}{IPv4}$/) {

    my $path2hostsfile = 'C:/Windows/System32/drivers/etc/hosts';
    my @hostsfile;

    {
        open(my $from_hostsfile, '<', $path2hostsfile) or die "Could n
+ot open $path2hostsfile for reading";
        @hostsfile = <$from_hostsfile>;
    }

    foreach my $line (@hostsfile) {
        next unless $line =~/^\s*$RE{net}{IPv4}\s+legba/; # skip unles
+s it is the default entry
        $line = "$ARGV[0]    legba\n";  # change the default host. $li
+ne is an alias for the corresponding element of @hostsfile!
    }

    {
        open(my $to_hostsfile,   '>', $path2hostsfile) or die "Could n
+ot open $path2hostsfile for writing";
        print $to_hostsfile @hostsfile;
    }
}
else {
    print "Missing or wrong argument!\nusage: set_default_host.pl defa
+ult_IP\n";
}
[download]

The program checks if this argument is present and is indeed an IP.

You will have to adapt the program slightly so the regex matches your default host. It is unlikely your default host will be called 'legba' although obviously that is highly recommended!

Update: added "or die ..." to open

Thank you all for your responses. You are correct in that I should have provided more detail. Normally I would have. I will blame the late hour of the posting and my failed attempts to get anything working on my own.

CountZero, you hit the situation precisely on the head. Thank you very much for the detailed example! The regular expressions search for the correct line to replace the IP address on is the main part I was having issues with.

-nas

This is what I came up with based on the information provided and the desire to have the user prompted for the updated IP address.

Please let me know if I'm making some serious Perl mistakes or if this looks good. Hints about better coding are always appreciated.

Update: Removed the code here. I hadn't tested it on the intended workstation before posting it and it turned out that it didn't work properly because the laptop image didn't include the Regex module.

Thanks once again for the guidance!