my $regex = qr(/.../);

I assume you meant just qr(...).

If $regex is not anchored at the start of the string/line, you can build

my $negated = qr{^(?!.*?$regex)}s;
[download]

(Update: Thinking a bit more about it I came to the conclusion this might even work with anchored regexes. I should test this and update my post again...)

Note that this is different in how many characters are consumed by the negation (here always none).

In theory any regular expression can be negated, but then again perl's "regexes" aren't regular at all.

Second update: Here's a small test script to find out if the negation works. Of course it needs far more test ;-)

#!/usr/bin/perl
use warnings;
use strict;
use Test::More qw(no_plan);

# first item:  regex
# second item: list of strings that regex should match
# third item:  list of strings that negated regex should match
my @r = (
    [qr{a},  ['a'],      ['', 'b']],
    [qr{^a}, [qw(a ab)], ['', 'b', 'ba']],
    [qr{a$}, [qw(a ba aba)], ['', 'b', 'ab']],
);

for (@r){
    my ($re, $pass, $fail) = @$_;
    my $negated = qr{^(?!.*?$re)};
    for (@$pass){
        like   $_, $re;
        unlike $_, $negated;
    }
    for (@$fail){
        like   $_, $negated;
        unlike $_, $re;
    }
}
[download]

Also see the thread Negating Regexes: Tips, Tools, And Tricks Of The Trade

  
  my $match   = sub { $_[0] =~ /.../ };
  my $negated = sub { not $match->(@_) };
[download]

Now that's some Higher Order Perl I can live with!

-sam

Just negate where desired and leave it at that. That's why !~ is included in the language, after all.