sub {1;} returns a reference to a subroutine that returns 1 when invoked.

>perl -le"$cb = sub {1;}; print $cb->()"
1
[download]

my $x = sub {1; };
print $x->();
[download]

and what would be the use of such construct?

As a default value.

Suppose you write a sub (or module) that processes some values, and you want to offer the caller the possibility to filter some of them. Now you've got two options:

sub process {
   my ($data, $filter) = @_;
   # lengthy calculations with $data here ...
   # in that length calculation you have to decide
   # if you continue with your calculation:

   for (@$data){
   if ($filter) {
       if ($filter->($_)){
          push @$data, other_lengthy_calculation($_);

       }
   } else {
       push @$data, other_lengthy_calculation($_);
   }
}
# second option:
sub process {
   my ($data, $filter) = @_;

   # provide a default value for $filter
   $filter = sub {1;} unless $filter;

   # lengthy calculations with $data here ...
   # in that length calculation you have to decide
   # if you continue with your calculation:

   for (@$data){
   if ($filter->($_)) {
       push @$data, other_lengthy_calculation($_);
   }
}
[download]

You can see that the construct with the default value is much shorter (3 instead of ~8 lines), and it's much cleaner.

If you're interested in more details on callbacks, anonymous subs and many more advanced techniques, I strongly recommend the book "Higher Order Perl" by Mark Jason Dominus.

It allows

my $rv = $args{'Post'} ? $args{'Post'}->() : 1;
[download]

to be simplified to

my $rv = $args{'Post'}->();
[download]

Or if the return value isn't checked, it allows

$args{'Post'} and $args{'Post'}->();
[download]

to be simplified to

$args{'Post'}->();
[download]

(sub{} would have been sufficient in the latter case.)

It's impossible to say without seeing the rest of the code. I expect that in context it's a sensible default if the user doesn't specify a function himself.

sub {return 1;}
[download]

As others have said, the code provides a default anonymous sub for the 'Post' attribute of $self. Since the anonymous sub aspect of this has been well covered, I'll comment on the default value side of things, with a slight detour into 'or' vs '||';

The code snippet you posted threw me off balance for half a second--setting default values is usually done using '||'--the high precedence logical or operator.

Perl has two logical or operators, '||' and 'or'. They identical except in terms of precedence. '||' has a high precedence and 'or' has a low precedence.

$foo = $bar || 'baz';
# is identical to
$foo = ( $bar or 'baz');
[download]

Common usage for each operator:

open( $fh, '>', $filename ) or die "Unable to open file: $!";

my $foo = $bar || 'baz';
[download]

Now, lets look at a couple ways to set a default value:

# Original code
$self->{'Post'} = ($args{'Post'} or sub {1;});

# High precedence or
$self->{'Post'} = $args{'Post'} || sub {1};

# Ternary operator
$self->{'Post'} = $args{'Post'} ? $args{'Post') : sub {1};

# Using '||' for a numeric value.
$self->{'Number'} = $args{'Number'} || 10;
[download]

This idiom is a common, compact, and readable way to set default values. However there is a trap for the unwary here. If the value you are testing may legitimately evaluate to false, your default value will be spuriously assigned. Take a look at the code below for an example of this bug.

foo();
foo(23);
foo(0);

sub foo {
    my $number = shift || 10;
    print "My number is $number\n";
}

__END__ #OUTPUT:
My number is 10
My number is 23
My number is 10
[download]

So, if you use this idiom, make sure you understand how your acceptable values are treated in boolean context (whether they evaluate to TRUE or FALSE).

Update: as DrHyde points out, if you are using Perl 5.10, the truly lovely defined-or operator solves this problem very nicely.

foo();
foo(23);
foo(0);

sub foo {
    my $number = shift // 10;
    print "My number is $number\n";
}

__END__ #OUTPUT:
My number is 10
My number is 23
My number is 0
[download]

However there is a trap for the unwary here. If the value you are testing may legitimately evaluate to false, your default value will be spuriously assigned.

That's solved by using the defined-or operator "//" that's new in perl 5.10. However, because it's so new it's probably not a good idea to use it yet for anything you upload to the CPAN :-)