my $x = dopen( '/dev/null', 'file-not-found', '/etc/passwd' );

sub dopen {
    my @t = map {
        my $fh;
        open $fh, '<', $_ and <$fh> or warn "Can't open `$_': $!\n";
    } @_;
    \@t;
}
__END__
Can't open `/dev/null':
Can't open `file-not-found': No such file or directory
[download]

That has a different problem. It reports an error just because the file happens to be empty.

What's wrong with the ternary operator?

sub dopen {
    my @t = map {
        my $fh;
        open $fh, '<', $_ ? 
          <$fh> :
          warn "Can't open `$_': $!\n";
    } @_;
    \@t;
}
[download]

Oh, no, please, don't tell me! It would put into @t the return value of every warning issued. (Yours would, too.) So, it must be:

          do { warn "Can't open `$_': $!\n"; () }
[download]

or

          (warn "Can't open `$_': $!\n")[()]
[download]

Horrible, I know! (In both cases.)

How about this, then:

my $x = dopen( '/dev/null', 'file-not-found', '/etc/passwd' );

sub dopen {
    my $out = [];
  FILE:
    foreach my $file ( @_ ) {
        my $fh;
        if ( ! open $fh, '<', $file ) {
            warn "Can't read '$file': $!\n";
            next FILE;
        }
        push @{$out}, <$fh>;
    }
    return $out;
}
__END__
Can't read 'file-not-found': No such file or directory
[download]

Looks good! It's readable, it complains at the right times, and it doesn't die when I meant it to warn.

Well, it's an "obvious" solution. Except that instead of dereferencing $out at every iteration I would maintain it as an array and take a reference to it at the end. (Incidentally, thanks to autovivification, you don't need to initialize to an empty arrayref.) I'm far from being an optimization-fanatic, but I don't like doing useless operations.